通过类型修改将一个 csv 标头复制到另一个 csv

Question

我想通过一些修改将一个 csv 标题逐行复制到另一个

输入 csv

name,"Mobile Number","mobile1,mobile2",email2,Address,email21
test, 123456789,+123456767676,a@test.com,testaddr,a1@test.com
test1,7867778,8799787899898,b@test,com, test2addr,b2@test.com

在新的 csv 中，这应该是这样的，并且还应该创建文件。对于 sting 列，我将传递列名，因此只有该列将转换为字符串

name.auto()
Mobile Number.auto()
mobile1,mobile2.string()
email2.auto()
Address.auto()
email21.auto()

正如您在上面看到的，所有这些带有类型修改的标题应该插入不同的行中

我尝试过使用以下命令，但这仅适用于复制第一行

sed '1!d' input.csv > output.csv

Answer 1

您也可以试试这个替代的gnu awk 命令：

awk -v FPAT='"[^"]+"|[^,]+' 'NR == 1 {
   for (i=1; i<=NF; ++i)
      print gensub(/"/, "", "g", $i) "." ($i ~ /,/ ? "string" : "auto") "()"
   exit
}' file

name.auto()
Mobile Number.auto()
mobile1,mobile2.string()
email2.auto()
Address.auto()
email21.auto()

---

或者使用sed:

sed -i -e '1i 1234567890.string(),My address is test.auto(),abc3@gmail.com.auto(),120000003.auto(),abc-003.auto(),3.com.auto()' -e '1d' test.csv

Answer 2

编辑：根据 OP 的评论仅打印第一行（标题），请尝试以下操作。

awk -v FPAT='[^,]*|"[^"]+"' '
FNR==1{
  for(i=1;i<=NF;i++){
    if($i~/^".*,.*"$/){
      gsub(/"/,"",$i)
      print $i".string()"
    }
    else{
      print $i".auto()"
    }
  }
  exit
}
' Input_file > output_file

---

---

您能否尝试使用 GUN awk 进行跟踪、编写和测试，并附上示例。

awk -v FPAT='[^,]*|"[^"]+"' '
FNR==1{
  for(i=1;i<=NF;i++){
    if($i~/^".*,.*"$/){
      gsub(/"/,"",$i)
      print $i".string()"
    }
    else{
      print $i".auto()"
    }
  }
  next
}
1
' Input_file

说明：为上述添加详细说明。

awk -v FPAT='[^,]*|"[^"]+"' '  ##Starting awk program and setting FPAT to [^,]*|"[^"]+".
FNR==1{                        ##Checking condition if this is first line then do following.
  for(i=1;i<=NF;i++){          ##Running for loop from i=1 to till NF value.
    if($i~/^".*,.*"$/){        ##Checking condition if current field starts from " and ends with " and having comma in between its value then do following.
      gsub(/"/,"",$i)          ##Substitute all occurrences of " with NULL in current field.
      print $i".string()"      ##Printing current field and .string() here.
    }
    else{                      ##else do following.
      print $i".auto()"        ##Printing current field dot auto() string here.
    }
  }
  next                         ##next will skip all further statements from here.
}
1                              ##1 will print current line.
' Input_file                   ##Mentioning Input_file name here.