在子项目中继承 gradle 插件

Question

我想避免冗余，因此我得到了一个“共享”项目，其中包含如下所示：

plugins {
    id "org.flywaydb.flyway" version "4.2.0"
}

repositories {
    mavenCentral()
    jcenter()
}

apply plugin: "java"

dependencies {
    compile "commons-io:commons-io:2.4"

    // ...
}

然后我还有我的常规项目，它们从我的共享项目中继承编译依赖项，如下所示：

apply plugin: "java"

repositories {
    mavenCentral()
    jcenter()
}

dependencies {
    compile project(":shared")
    testCompile project(":shared")
}

有什么方法可以让我的常规项目也继承插件块或实际插件？

Answer 1

不是继承。在我看来，您可以通过从根项目配置子项目来实现您想要做的事情。基本上在你的根build.gradle（将配置你的根项目的脚本）你可以写：

subprojects {
  // configuration
}

您可能可以摆脱您的共享项目并将其放在根项目的build.gradle：

plugins {
  id "org.flywaydb.flyway" version "4.2.0" apply false
}

subprojects {    
    repositories {
        mavenCentral()
        jcenter()
    }

    apply plugin: "java"
    apply plugin: "org.flywaydb.flyway"

    dependencies {
        compile "commons-io:commons-io:2.4"

        // ...
    }
}

这样，您的所有子项目都将使用相同的闭包进行配置 - 这相当于将 subprojects 块中的所有内容复制粘贴到您各个子项目的 build.gradle 文件中。与您最初的解决方案相比，优势在于能够应用插件、配置扩展，以及您通常可以做的所有事情。

附带说明，repositories 块中不需要 jcenter() 和 mavenCentral - jCenter 是 mavenCentral 的超集，并且是首选