如何保存具有透明度的png文件？

Question

我正在使用 Barcode Studio 2011 将 QR 码绘制到 Graphics32 - TImage32 组件中，我想将其保存为 png 格式，但白色是透明的，这是我在 Graphics32 的 OuterColor 中指定的。

OnFormCreate 我刚刚

procedure TForm1.FormCreate(Sender: TObject);
begin
  psBarcodeComponent1.BarCode := 'some text here...';
end;

目前我已将绘画分配给按钮单击事件

procedure TForm1.Button8Click(Sender: TObject); // Paint the barcode
var
  bmp: TBitmap32;
  Coords: TRect;
begin
 bmp := TBitmap32.Create;
 bmp.SetSize(image.Width, image.Height);
 bmp.Canvas.Brush.Color := color;
 bmp.Canvas.Rectangle(-1, -1, image.Width+2, image.Height+2);

 bmp.DrawMode := dmTransparent;
 bmp.OuterColor := clWhite;

 // make Coords the size of image
 Coords := Rect(0,0,image.Width,image.Height);
 psBarcodeComponent1.PaintBarCode(bmp.Canvas, Coords);
 image.Bitmap.Assign(bmp);
end;

我正在使用 Vampyre Imaging Library 将位图转换为 PNG 格式，但我很乐意使用任何库、函数和建议 - 我已经尝试这样做将近一周了！我已经阅读并重新阅读了 graphics32 和 Vampyre Imaging Library 的文档，但我没有尝试将白色转换为透明颜色。我尝试过 clWhite、clWhite32 并将 drawMode 设置为 dmBlend 并应用 ChromaKey 函数都无济于事，但很沮丧，咖啡和一点啤酒也;)

这就是我保存它的方式...

procedure TForm1.Button7Click(Sender: TObject); // Save with Vampyre Imaging Lib
{ Try to save in PNG format with transparancy }
var
  FImage: TSingleImage;
begin
  FImage := TSingleImage.Create;
  ConvertBitmap32ToImage(image.Bitmap, FImage);
  FImage.SaveToFile('VampyreLibIMG.png');
end;  

这会生成黑色缩略图，在 Windows 照片查看器中查看时它是完全透明的。

我希望我提供了足够的信息并且有人能够帮助我。

克里斯

Answer 1

这种方法对我有用：

uses GR32, GR32_PNG, GR32_PortableNetworkGraphic;

var
  Y: Integer;
  X: Integer;
  Png: TPortableNetworkGraphic32;

  function IsWhite(Color32: TColor32): Boolean;
  begin
    Result:= (TColor32Entry(Color32).B = 255) and
             (TColor32Entry(Color32).G = 255) and
             (TColor32Entry(Color32).R = 255);
  end;

begin
  with Image321 do
  begin
    Bitmap.ResetAlpha;
    for Y := 0 to Bitmap.Height-1 do
      for X := 0 to Bitmap.Width-1 do
      begin
        if IsWhite(Bitmap.Pixel[X, Y]) then
          Bitmap.Pixel[X,Y]:=Color32(255,255,255,0);
      end;
    Png:= TPortableNetworkGraphic32.Create;
    Png.Assign(Bitmap);
    Png.SaveToFile('C:\Temp\NowTransparent.png');
    Png.Free;
  end;
end;

这使用GR32 PNG library。这是一种非常直接的方法，将所有白色像素设置为透明。

PS：Image321 是一个TImage32 组件，包含我的TBitmap32。

Answer 2

您还没有指定 Delphi 版本，但是如果您的 delphi 版本有“PngImage”（我相信它带有 D2009+），下面的代码可以完美运行（在 Gimp 和 Windows 照片查看器中加载，它会绘制一个框架和一些文本有透明背景，随意玩吧：

uses
  PngImage;

procedure TForm1.OnBtnClick(Sender: TObject);
var
  bmp: TBitmap;
  png: TPngImage;
begin
  bmp := TBitmap.Create;
  bmp.Width := 200;
  bmp.Height := 200;

  bmp.Canvas.Brush.Color := clBlack;
  bmp.Canvas.Rectangle( 20, 20, 160, 160 );

  bmp.Canvas.Brush.Style := bsClear;
  bmp.Canvas.Rectangle(1, 1, 199, 199);

  bmp.Canvas.Brush.Color := clWhite;
  bmp.Canvas.Pen.Color := clRed;
  bmp.Canvas.TextOut( 35, 20, 'Hello transparent world');

  bmp.TransparentColor := clWhite;
  bmp.Transparent := True;

  png := TPngImage.Create;
  png.Assign( bmp );
  png.SaveToFile( 'C:\test.png' );

  bmp.Free;
  png.Free;
end;