如何处理 Access 中插入的参照完整性

Question

我正在处理我从同事那里接手的 Access 项目。存在三个表：rules、overview 和 relationship。 relationship 表有两个字段，每个字段都是链接到其他两个表中的主键的外键。我有一个表格中rules 表的数据表视图，我可以在其中毫无问题地删除记录。但是，当我尝试在rules 表中插入一条记录时，该记录将插入到rules 表中，但没有匹配的记录插入到relationship 表中。我检查了“强制参照完整性”，以及“级联更新相关字段”和“级联删除相关记录”。我做了一个天真的假设，认为这会处理插入，但显然我错了。所以我现在想知道处理这个问题的最佳方法 - 我是否为表单的 After Insert 事件编写一些 VBA，相应地将记录插入到 relationship 表中？

Answer 1

通常的方法是要么有一个表单将记录插入到规则中，该规则基于一个包含关系表的查询，例如一个允许用户选择相关概览的组合，或者一个表单/子表单集使用合适的主/子字段。在 NorthWind 示例数据库中，Order Detail 表是您的 Relationship 表的一个示例，它使用了令人讨厌的查表反功能，但您可能会得到一些进一步研究的想法。

选项 1 的更详细说明

表格

概览
身份证
概述

规则
身份证
规则

关系
RulesID ) 由两个 FK 组成的 PK
概览ID)

关系

数据

建议 1 查询设计

请注意，关系中的两个字段都包含在查询中。不需要显示规则中的 ID，因为它是一个自动编号字段，但为了简单起见，将其包含在此处。

如果删除了一行，则两个表中的记录都将被删除。

您不能违反参照完整性。您需要先创建所有概览，然后才能使用，或者提供不同的添加概览的方法。

如果您更新RulesID 和OverviewID，一条记录将添加到关系表中，但不会添加到规则中。

如果您更新 OverviewID 和 Rule，记录将同时添加到关系和规则中。

如果您创建一个连续的表单，您就可以以更加用户友好的方式获得以上所有内容，并且具有更多控制权。您可以使用组合框让用户选择更友好的概览描述，而不是 ID，您可以利用 NotInList 事件添加新概览。

请注意，到目前为止，这还不需要一行代码。这就是 Access 的力量。

Answer 2

如果有问题的键是自动编号 (IDENTITY) 并且一个表引用另一个表（通过外键），那么您可以创建一个 VIEW 连接两个表，插入到视图中，然后自动编号值得到自动复制到参考表。这是一个快速演示：

Sub RulesOverview()
  On Error Resume Next
  Kill Environ$("temp") & "\DropMe.mdb"
  On Error GoTo 0

  Dim cat
  Set cat = CreateObject("ADOX.Catalog")

  With cat
    .Create _
    "Provider=Microsoft.Jet.OLEDB.4.0;" & _
    "Data Source=" & _
    Environ$("temp") & "\DropMe.mdb"

    With .ActiveConnection

      Dim Sql As String

      Sql = _
      "CREATE TABLE Rules ( " & _
      " ID INTEGER IDENTITY NOT NULL UNIQUE,  " & _
      " Rule VARCHAR(30) NOT NULL UNIQUE " & _
      ")"

      .Execute Sql

      Sql = _
      "CREATE TABLE Overview ( " & _
      " OverviewID INTEGER IDENTITY NOT NULL UNIQUE, " & _
      " Overview VARCHAR(30) NOT NULL UNIQUE " & _
      ")"

      .Execute Sql

      Sql = _
      "CREATE TABLE Relationship ( " & _
      " RuleID INTEGER NOT NULL " & _
      "    REFERENCES Rules (ID) " & _
      "    ON DELETE CASCADE, " & _
      " OverviewID INTEGER " & _
      "    REFERENCES Overview (OverviewID) " & _
      "    ON DELETE SET NULL, " & _
      " Name VARCHAR(20) NOT NULL, " & _
      " UNIQUE (RuleID, OverviewID) " & _
      ")"

      .Execute Sql

      Sql = _
      "CREATE VIEW RulesRelationship AS " & _
      "SELECT Rules.ID, " & _
      "       Rules.Rule, " & _
      "       Relationship.RuleID, " & _
      "       Relationship.Name " & _
      "  FROM Rules INNER JOIN Relationship " & _
      "          ON Rules.ID = Relationship.RuleID;"

      .Execute Sql

      Sql = _
      "INSERT INTO RulesRelationship (Rule, Name) " & _
      "   VALUES ('Don''t run with scissors', " & _
      "           'Initial scissors');"

      .Execute Sql

      Sql = _
      "SELECT * FROM RulesRelationship;"

      Dim rs
      Set rs = .Execute(Sql)
      MsgBox rs.GetString

    End With
    Set .ActiveConnection = Nothing
  End With
End Sub