Monster Search - 循环（字符串搜索 + 整数插入）

Question

我有一个名为 strMonsterEssay 的大字符串（超过 255 个字符）。

在这篇文章中重复了一个字符串字符，其格式与 Monster X 完全相同，我希望能够找到最大的怪物编号。整篇文章中都有怪物 1、怪物 2...怪物 X。注意，最多可能有 99 个怪物。

在代码的最后，我希望能够说“有 25 个怪物”之类的话。

我不知道在“喜欢”搜索循环中输入整数的语法。这是我到目前为止的代码，希望能得到一些帮助：

Dim MonsterNum As Integer 
Dim strHowManyMonsters As String

MonsterNum = 1

For MonsterNum 1 to 99

    If (NOT strMonsterEssay like ("*Monster&Char(32)&'"MonsterNum + 1"'*") And strMonsterEssay like ("*Monster&Char(32)&'"MonsterNum"'*") Then strHowManyMonsters = "There are '"MonsterNum"' Monsters."

    Else: strHowManyMonsters = "There are no Monsters."
    
    End If

Next MonsterNum

Answer 1

试试这个

Dim MonsterNum As Integer
Dim strHowManyMonsters As String

strHowManyMonsters = "There are no Monsters."

For MonsterNum = 99 To 1 Step -1
  
    If strMonsterEssay Like "*[mM]onster " & MonsterNum & "*" Then
        strHowManyMonsters = "There are " & MonsterNum & " Monsters."
        Exit For
    End If
  
Next MonsterNum

注意使用[mM] 进行测试，使搜索不区分大小写。我认为像这样使用 VBA 的 Instr() 函数可能是一个更好的选择：

If InStr(1, strMonsterEssay, "Monster " & MonsterNum, vbTextCompare) > 0 Then

还要注意倒数。

Answer 2

请使用下一个功能。如果所有现有的 'Monster' 字符串后跟不同的数字，则数字无关紧要。数Monster就够了。

Function CountMonsters(FullString As String, strMonster As String) As Long
    CountMonsters = UBound(Split(FullString, strMonster))
End Function

可以这样调用：

Sub testFindMonsters()
  Dim strMonsterEssay As String
  strMonsterEssay = "Monster 1 and Monster 2 goes to school. Monster 3 is waitting for the first two..."
  MsgBox "There are " & CountMonsters(strMonsterEssay, "Monster") & " Monsters."
End Sub

如果必须返回“最大怪物号”，同样的函数会这样调用：

Sub testMaxMonsterNumber()
   Dim MonsterNum As Long, strMonsterEssay As String, maxNo As Long, i As Long
   Dim strHowManyMonsters As String
    
   strMonsterEssay = "Monster 1 and Monster 2 goes to school. Monster 3 is waiting for the first two. However, Monster 1 and Monster 2 saw Monster 3 waiting and went a different way. Monster 3 waited for a long time for Monster 1 and Monster 2 but they never showed up"
    For i = 99 To 1 Step -1
        If CountMonsters(strMonsterEssay, "Monster " & i) > 0 Then
            maxNo = i: Exit For
        End If
    Next
    If maxNo > 0 Then
       MsgBox "There are " & maxNo & " Monsters."
    Else
       MsgBox "There are no Monsters."
    End If
End Sub

但是如果“怪物32正在等待前两个”，它会返回32。我问你连续怪物编号'规则'，但你没有说...