如果满足我的条件，如何循环回当前单元格？

Question

这是我关于 SO 的第一篇文章，所以我希望我这样做是正确的。

我正在尝试从我的数据中删除满足以下条件的行：

1. 第一列的值与其下面的单元格不同
2. 第三列的值等于它下面的单元格

我的代码示例如下所示：

For Each Cell In MyRangeA3
        If Cell.Value <> Cell.Offset(1).Value Then
            If Cell.Offset(, 2).Value = Cell.Offset(1, 2).Value Then
            Cell.Offset(1).EntireRow.Delete
            End If
        End If
Next Cell

我面临的问题是我的宏转到下一个单元格，因此我必须再次重新运行我的宏才能删除符合我条件的下一行。我应该在我的代码中添加什么才能一次性完成此操作？

Answer 1

您可以收集匹配的单元格，然后删除相应的行：

' ... your code    

Dim toDel As Range
For Each cell In MyRangeA3
    If cell.Value <> cell.Offset(1).Value Then
        If cell.Offset(, 2).Value = cell.Offset(1, 2).Value Then
            If toDel Is Nothing Then    'collect cells to further delete
                Set toDel = cell.Offset(1)
            Else
                Set toDel = Union(toDel, cell.Offset(1))
            End If
        End If
    End If
Next cell
' delete all rows for appropriate collected cells
' debug the script before actually deleting lines with, e.g. 
' toDel.EntireRow.Interior.ColorIndex = 3 instead toDel.EntireRow.Delete
If Not toDel Is Nothing Then toDel.EntireRow.Delete

' your code ...