构建一个没有重复的随机名称生成器

Question

我目前正在指派我组织的成员与其他观点成员会面。我有三个标准：

1. 每个透视成员都必须与 6 个不同的当前成员会面
2. 当前成员不能与同一个透视成员成员两次
3. 配对必须是随机的

我已经在 Excel 中尝试了随机名称/数字生成器：

=INDEX($A:$A,RANDBETWEEN(1,COUNTA($A:$A)),1) 

...虽然有用，但它并不能确保每个视角都与 6 个不同的现任成员会面，或者不会确保每个视角都与某人会面两次。

我还添加了一个图表，我想红色是透视成员，蓝色是当前成员，绿色是我对配对进行排序的位置（基于当前成员）。

请帮助我，我完全不知道如何做到这一点。

Answer 1

有多种方法可以随机化列表...

使用 VBA 随机化选择

使用excel-vba 的一种方法是遍历工作表上选定（突出显示）的单元格，用单元格值（以随机顺序）填充数组，然后用数组值替换原始值：

Sub randomizeSelection()

    Dim arrOut() As String
    Dim x As Integer, n As Integer

    Randomize 'reseed random number generator

    With Selection '"Using the selected (highlighted) cells..."

        ReDim arrOut(1 To .Count) 'set array to same size as selection

        'make sure multiple cells are selected
        If .Count <= 1 Then
            MsgBox "Must select at least 2 cells to randomize."
            Exit Sub
        End If

        For x = 1 To .Count 'loop through selection
            Do
                n = Int(Rnd() * .Count) + 1 'pick random position in array
            Loop Until arrOut(n) = "" 'if position is 'occupied' then repeat loop

            arrOut(n) = .Item(x) 'store item in the new (random) position
        Next x

        'repopulate selection with items from [arrOut]
        For x = 1 To .Count
            .Item(x) = arrOut(x)
        Next x

    End With

End Sub

它适用于一维的选择：

…或，二维：

更多信息：

• The Complete Guide to Using Arrays in Excel VBA

• MSDN：Rnd Function (VBA)

• MSDN : Randomize Statement (VBA)

---

在没有 VBA 的情况下随机化工作表列表

随机化列表的另一种方法（没有 VBA） 是使用附加的（“帮助”）列或行，以及 Excel 的内置 排序 功能.

1. 在要排序的列表相邻的列或行中，添加函数：

   =RAND()

   ...并将函数按原样“填充”（或复制和粘贴）到列表的长度。

2. 突出显示列表和添加的“辅助单元格”，然后按“辅助单元”排序。

请注意，此方法仅适用于 单个 列/行中的列表。要随机化二维列表中的单元格，请使用上述 VBA 方法。

对垂直列表进行随机排序：

随机排序水平列表：

---