将数据从一行转换为多行以创建产品 SKU

Question

我有很多关于电子商务商店的产品数据行，包括尺寸和颜色等。我需要每个变体都在自己的行上，这样我就可以上传所有这些数据。我认为我需要某种 Excel 公式或 VBA 来执行此操作。

Title            Size
Ladies Dress    S,M,L,XL,XXL
Men's Trousers  S,M,L,XL,XXL

所需数据：

Title           Size
Ladies Dress    S
Ladies Dress    M
Ladies Dress    L
Ladies Dress    XL
Ladies Dress    XXL
Men's Trousers  S
Men's Trousers  M
Men's Trousers  L
Men's Trousers  XL
Men's Trousers  XXL

我在 Google 电子表格上放置了 2 个示例行，以便分享。

Sample

Answer 1

这是我为 PC 编写子程序的方法；我会尽量保持函数调用的通用性和跨平台性。

Option Explicit

Sub sizeExpansion()
    Dim i As Long, szs As Variant

    With Worksheets("sheet1")
        For i = .Cells(.Rows.Count, "B").End(xlUp).Row To 2 Step -1
            szs = Split(.Cells(i, "B").Value2, ",")
            If CBool(UBound(szs)) Then
                .Cells(i, "A").Resize(UBound(szs), 1).EntireRow.Insert
                .Cells(i, "A").Resize(UBound(szs) + 1, 1) = .Cells(UBound(szs) + i, "A").Value2
                .Cells(i, "B").Resize(UBound(szs) + 1, 1) = Application.Transpose(szs)
            End If
        Next i
    End With

End Sub