如何从excel单元格中的句子中提取8个字母的大写单词？

Question

示例 - 单元格中的句子 A1 是 WO# 000000.0 for ITSHTJ in Q0 20000_ITAI0006:TBD Replacement PO，我想提取 ITAI0006。

我在UDF下面用过，但是没用。

Function findUcase(Rng As Range) As Boolean
    Dim Txt
    Dim Desc() As String

    Desc = Split(Rng.Value, " ")
    For Each Txt In Desc
        If (UCase(Txt) = Txt) Then
            findUcase = True
            Exit Function
        End If
    Next
End Function

Answer 1

你可以试试：

B1中的公式：

=FILTERXML("<t><s>"&SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1,"_"," "),":"," ")," ","</s><s>")&"</s></t>","//s[string-length(.)=8][translate(.,'ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789', '')='']")

XPath 表达式过滤节点的位置：

• [string-length(.)=8] - 所有 8 个字符长的子字符串；
• [translate(.,'ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789', '')=''] - 确保当所有大写字母字符和数字都被替换为空时，节点也将不等于空。

---

请注意，一旦您制定了更具体的规则，公式方法会变得更加简单，例如：

• 是否总是第一个冒号前的 8 个字符？
• 是否总是在下划线和冒号之间？
• 总是字母数字吗？
• 等

Answer 2

Regex 方法 - 这将返回给定单元格中的任意 8 个字符（A-Z 和数字）。

Function findUcase(Rng As Range) As String
    If Rng.Cells.Count = 1 Then
        Dim regex As Object
        Set regex = CreateObject("vbScript.Regexp")
        
        regex.Global = False
        regex.Pattern = "[\dA-Z]{8}"
        If regex.Test(Rng.Value) Then
            findUcase = regex.Execute(Rng.Value)(0)
        End If
    End If
End Function

编辑 - 另一个版本将返回字符串中至少包含 A-Z 的字符串，并且还支持 8 个字符的格式，任意数量的 AZ，一个空格，然后是任意数量的数字。

Function findUcase(Rng As Range) As String
    Const firstPattern As String = "[\dA-Z]{8}"
    Const secondPattern As String = "[A-Z]+ [\d]+"
    Const charLimit As Long = 8
    
    If Rng.Cells.Count = 1 Then
        Dim rngValue As String
        rngValue = Rng.Value
        
        Dim regex As Object
        Set regex = CreateObject("vbScript.Regexp")
        
        Dim matchColl As Object
        Dim match As Object
            
        regex.Global = True
        regex.Pattern = firstPattern
        If regex.test(rngValue) Then
            Set matchColl = regex.Execute(rngValue)
            
            For Each match In matchColl
                If Not IsNumeric(match) Then
                    findUcase = match
                    Exit For
                End If
            Next match
        Else
            regex.Pattern = secondPattern
            If regex.test(rngValue) Then
                Set matchColl = regex.Execute(rngValue)
                For Each match In matchColl
                    If Len(match) = charLimit Then
                        findUcase = match
                        Exit For
                    End If
                Next match
            End If
        End If
    End If
    
    Set matchColl = Nothing
    Set regex = Nothing
End Function