数组下标超出范围错误 - 不知道为什么？

Question

我已经声明了一个这样的数组Dim rArray() As Variant但是当我尝试使用存储在其中的值时（如下所示），我得到一个下标超出范围错误。 UBound(rArray) 和 LBound(rArray) 都返回值 14 和 1，但错误发生在 Debug.Print 行。

如果我使用下面的 for 语句

For Each rArr in rArray

然后它可以正常工作，但出于创建此数组的目的，我需要灵活地选择按该顺序存储的每个项目——这意味着我需要使用下标来引用它们。

我尝试了多种方法来尝试解决这个问题，但没有成功，我几乎半天的时间都在这个问题上。谁能指出我需要改变什么才能让它工作。

Set rng = Range("D4", Range("D4").End(xlDown))
rng.NumberFormat = "0"
rArray = rng.Value

For x = UBound(rArray) To LBound(rArray) Step -1
    Debug.Print rArray(x)
Next x

编辑：另一个值得一提的事实是，数组是在函数中声明和使用的，但它没有从函数传递或传递给函数。 Functions中不能声明和使用数组吗？

Answer 1

当您将工作表值分配给变量数组时，您总是最终得到一个基于 1 的二维数组（例如，1 到某物，1 到某物; 从不 0 表示某事，0 表示某事）。如果您从单个列中获取值，则第二个 Rank 仅为 1 到 1。

这可以用以下来证明。

Dim x As Long, rArray As Variant, rng As Range

Set rng = Range("D4", Range("D4").End(xlDown))
rng.NumberFormat = "0" 'don't really understand why this is here
rArray = rng.Value

Debug.Print LBound(rArray, 1) & ":" & UBound(rArray, 1)
Debug.Print LBound(rArray, 2) & ":" & UBound(rArray, 2)

For x = UBound(rArray, 1) To LBound(rArray, 1) Step -1
    Debug.Print rArray(x, 1)
Next x

所以你需要求数组第一排的元素；仅仅要求元素是不够的。