按接收日期获取消息数答案

【问题标题】：Get count of messages by received date按接收日期获取消息数
【发布时间】：2011-09-04 21:05:57
【问题描述】：

我有以下代码用于计算 Outlook 中的电子邮件总数：

Sub Test()

    Dim objOutlook As Object, objnSpace As Object, objFolder As Object
    Dim EmailCount As Integer

    Set objOutlook = CreateObject("Outlook.Application")

    Set objnSpace = objOutlook.GetNamespace("MAPI")

    On Error Resume Next

    Set objFolder = objnSpace.Folders("MyFolder").Folders("Spam")

    If Err.Number <> 0 Then
        Err.Clear
        MsgBox "No such folder."
        Exit Sub
    End If

    EmailCount = objFolder.Items.Count
    Set objFolder = Nothing
    Set objnSpace = Nothing
    Set objOutlook = Nothing

    MsgBox "Number of emails in the folder: " & EmailCount, , "Number of spam messages "

End Sub

谁能给我一些方法来计算一周中的某一天？

例子：

“星期一收到的消息数 = 476”
“周日收到的消息数 = 121”

甚至在特定日期

“2010 年 11 月 2 日收到的电子邮件数量”

【问题讨论】：

请注意，人们不喜欢被大喊——计算机在 30 多年前获得了小写字母，所以不要像图示那样进行批量大写输出。
你想去多少个星期一？还是说上周一？
@Sasquiha：例如所有星期一。如果我能得到一些基本上说的代码：如果电子邮件的发送日期=（（今天的日期）Mod 7）=0“嘿，这封电子邮件是在星期一发送给我的！”然后把这个的所有实例加起来（“你有 59 封电子邮件在星期一发送给你”）然后我可以摆弄这个并说（（今天的日期 + 1）Mod 7）=（嘿看！这封电子邮件是在星期二发送给我的！”等等。
@乔纳森：计算机获得了不同类型的格式，以便区分一系列散文。如果我在大写字母中对消息框的可视化不清楚或冒犯了您，我很抱歉。但是 - 重新格式化我的代码的荣誉！（Stack Overflow 的 UI 在这方面有点……不直观）
或者就在上周一！这需要我做更多的工作，但我迫切希望在这个阶段让一些宏工作！

标签： vba email outlook outlook-2003

【解决方案1】：

也许将参数（可选的 dteDate As Date）添加到整个方法/函数并在正文中包含以下代码

Select Case Weekday(dteDate)
  Case vbMonday  
    IsCorrectDay = True
  Case Else  
    IsCorrectDay = False
End Select

For Each MapiItem In MapiFolderInbox.Messages
  If MapiItem.TimeReceived = IsCorrectDay Then count = count + 1     
Next MapiItem

【讨论】：

或者，如果这不起作用，则可能替换 IsCorrectDay = True Case Else IsCorrectDay = False ****WITH**** dteDate = Date ..... ****and*** * ..... 如果 MapiItem.TimeReceived = Date.... 等
如果您在代码前加上 4 个空格，则可以缩进 :-)

【解决方案2】：

看起来您必须查看每条消息并使用 TimeReceived 属性。

For Each MapiItem In MapiFolderInbox.Messages
            If MapiItem.TimeReceived = dte Then count = count + 1
        Next MapiItem

或类似的东西。

【讨论】：

好的 - 但我不确定如何使用上面的代码。这似乎只是循环浏览所有电子邮件，因此计数最终将等于该特定文件夹中的电子邮件总数，而不代表在任何特定日期发送的电子邮件......？
它会循环浏览文件夹中的所有电子邮件，如果日期是你想要的，它只会加 1 来计数。如果您想要所有文件夹，您将在此之外有另一个循环来循环所有文件夹，而不仅仅是您上面提到的那个。
想必我要搜索的那一天是dte的反面？但是我需要做什么才能有一个变量来指定这个日期，以及我需要做什么来创建一个变量，该变量包含一个与我当天发送的电子邮件的出现次数有关的整数想？ :-&

【解决方案3】：

这就是我所拥有的。似乎没有任何简单的属性或方法可以为您提供所需的答案。我不知道是否有任何方法可以通过 SQL 查询引用邮件项目。如果有，那将是理想的方法。由于这似乎不可能，您唯一的选择是遍历文件夹（或文件夹）中的所有项目，并在一周中的几天有几个计数器变量。然后为每个项目增加相应的计数器。

主要问题只是弄清楚如何引用适当的对象。

在 MS Outlook 2003 中测试，似乎可以正常工作。但是 - 我没有检查它是否计算收件箱每个子文件夹中的每个项目，或者它是否只是计算收件箱本身中的项目，而不是收件箱子文件夹中的任何项目。反正就是她：

Sub CountEmailsByDayOfWeek()
 'count mail items by day-of-week
 'Isaac Comer, 6-3-2011

 Dim EmCtSun, EmCtMon, EmCtTue, EmCtWed, EmCtThu, EmCtFri, EmCtSat As Long

 Dim myInbox As Variant
 Dim BUNCH_OF_Items As Items
 Dim myInboxItem As Variant

 Set myInbox = GetNamespace("MAPI").GetDefaultFolder(olFolderInbox)
 Set BUNCH_OF_Items = myInbox.Items

 ' < Handle any errors like No such folder here >

 ' clear counters for each day-of-week 
 ' "EmCt" means "Email Count". It wasn't a good choice of variable name 
 ' because some "Items" aren't "Emails", but I'm not fixing it right now
 EmCtSun = 0: EmCtMon = 0: EmCtTue = 0: EmCtWed = 0: EmCtThu = 0: EmCtFri = 0: EmCtSat = 0


' disabled test case with the "first" item in Inbox--testing to make sure I had the object reference correct
'     Set myInboxItem = BUNCH_OF_Items(1)
'          With myInboxItem
'               Debug.Print Chr(34) & .Subject & Chr(34) & " Received: "; .ReceivedTime
'               Debug.Print DatePart("w", .ReceivedTime)
'          End With

 For Each myInboxItem In BUNCH_OF_Items
      With myInboxItem
           'disabled code that shows the subject line and received time
           'Debug.Print Chr(34) & .Subject & Chr(34) & " Received: "; .ReceivedTime
           Select Case DatePart("w", .ReceivedTime) ' get the numeric day-of-week corresponding to the vb constants
                Case vbSunday
                     EmCtSun = EmCtSun + 1
                Case vbMonday
                     EmCtMon = EmCtMon + 1
                Case vbTuesday
                     EmCtTue = EmCtTue + 1
                Case vbWednesday
                     EmCtWed = EmCtWed + 1
                Case vbThursday
                     EmCtThu = EmCtThu + 1
                Case vbFriday
                     EmCtFri = EmCtFri + 1
                Case vbSaturday
                     EmCtSat = EmCtSat + 1
           End Select
      End With
 Next

 ' output
 ' send output both to a msgbox and the immediate window.
 Debug.Print "Counts for Emails received Sunday, Monday, Tuesday, Wednesday, Thursday, Friday, and Saturday respectively."
 Debug.Print EmCtSun; EmCtMon; EmCtTue; EmCtWed; EmCtThu; EmCtFri; EmCtSat
 MsgBox _
      "Sunday:" & vbTab & vbTab & EmCtSun & vbCrLf & _
      "Monday:" & vbTab & vbTab & EmCtMon & vbCrLf & _
      "Tuesday:" & vbTab & vbTab & EmCtTue & vbCrLf & _
      "Wednesday:" & vbTab & EmCtWed & vbCrLf & _
      "Thursday:" & vbTab & EmCtThu & vbCrLf & _
      "Friday:" & vbTab & vbTab & EmCtFri & vbCrLf & _
      "Saturday:" & vbTab & EmCtSat, _
      vbOKOnly + vbInformation, "Count of Items By Day-of-week Received"
End Sub

如果此代码有帮助，请为我投票。我需要积分。 :-)

【讨论】：