如何在 Word 文档段落中连接尾注？

Question

我有一个包含 4000 多个尾注的 *.docx 文件。我的任务是将每个段落中的尾注（有 3 个或更多尾注）合并为一个大尾注。

例如。

输入：

单词单词{1}单词{2}单词单词{3}单词。

尾注：

{1} 尾注

{2} 尾注

{3} 尾注

输出：

单词单词单词单词单词{1}。

尾注：

{1} 尾注；尾注；尾注

所以我将有一个大的尾注而不是几个小的尾注。 我尝试过的：

Sub Macro1()
Dim i As Integer
Dim t As String
Dim tmp As String

tmp = ""
For i = 1 To Selection.Endnotes.Count Step 1
    t = Selection.Endnotes(i).Range.Text
    If tmp = "" Then
        tmp = Selection.Endnotes(i).Range.Text
    Else
        tmp = tmp & "; " & Selection.Endnotes(i).Range.Text
    End If
Next i

For i = Selection.Endnotes.Count To 1 Step -1
   Selection.Endnotes(i).Delete
Next i

Selection.Expand wdParagraph

ActiveDocument.Endnotes.Add Range:=Selection.Range, Text:=tmp
End Sub

它可以工作，但用户必须手动选择正确的段落。我不知道如何自动执行此过程 - 查找包含 3 个以上尾注的错误段落并将上面的代码应用于这些段落。 ActiveDocument.Paragraphs 项没有 Endnotes 属性。 请帮忙）

Answer 1

所以决定是：

Sub Macro1()
Dim i As Integer
Dim t As String
Dim tmp As String
Dim p As Paragraph
 
For Each p In ActiveDocument.Paragraphs
     If p.Range.Endnotes.Count > 3 Then
        tmp = ""
        For i = 1 To p.Range.Endnotes.Count Step 1
            t = p.Range.Endnotes(i).Range.Text
            
            If tmp = "" Then
                tmp = t
            Else
                tmp = tmp & "; " & t
            End If
        Next i

        For i = p.Range.Endnotes.Count To 1 Step -1
            p.Range.Endnotes(i).Delete
        Next i
    
        ActiveDocument.Endnotes.Add Range:=p.Range, Text:=tmp
     End If
Next p
 
End Sub