Excel VBA - .Find 工作簿之间的方法

Question

问题：
为什么引用不同的工作簿时Range.Find 方法不起作用？

问题： 我正在尝试在工作簿之间复制数据，但 Range.Find 方法因“运行时错误 1004”而停止。我在 Windows 7 机器上使用 Excel 2007。

详情： 在两个工作簿上，每个工作簿仅引用或使用 Sheet1。我有一个程序（ztest），大纲如下：

1. 格式化工作表
2. 遍历工作簿 #1 的 E 列中的所有单元格
3. 使用Range.Find 方法，在工作簿#2 的E 列中查找值
4. 找到后，设置工作簿 #1 偏移列 = 工作簿 #2 偏移列

我想用 .Find 来做这件事 - 不 使用 HLOOKUP 或类似的东西。

我已经稍微简化了代码，以缩小确切的范围。这里没有显示上面的第 4 步，但是错误出现在第 3 步，在包含.Find 方法的语句中：

Public Sub ztest2()
'set workbook titles
Const w1 As String = "05AR 20130920.xlsx"
Const w2 As String = "05AR 20130923.xlsx"
Dim cl As Variant

With Workbooks(w2).Worksheets(1)
  'format the sheet
  .Range("A1", "D1").EntireColumn.Hidden = True
  'loop through all cells column E of workbook #1
  For Each cl In .Range("E2", Cells(Rows.Count, "E").End(xlUp))
    'find value of current cell in column E, workbook #2
    Workbooks(w1).Worksheets(1) _
    .Range("E2", Cells(Rows.Count, "E").End(xlUp)) _
    .Find(what:=cl.Value, LookIn:=xlValues).Select
  Next
End With

End Sub

Answer 1

很好地构建代码非常重要，这样在理解它时就不会有困难。如果需要，请编写额外的代码行，以便即使您在 6 个月后看到代码，也可以识别代码的作用。还要完全限定您的对象。

试试这个（未测试）。我已经评论了代码。因此，如果您有不明白的地方，请回帖

Const w1 As String = "05AR 20130920.xlsx"
Const w2 As String = "05AR 20130923.xlsx"

Sub ztest2()
    Dim wb1 As Workbook, wb2 As Workbook
    Dim ws1 As Worksheet, ws2 As Worksheet
    Dim cl As Range, ws1Rng As Range, ws2Rng As Range, aCell as Range
    Dim lRowW1 As Long, lRowW2 As Long

    '~~> Define your workbook and worksheets here
    Set wb1 = Workbooks(w1)
    Set ws1 = wb1.Sheets(1)
    Set wb2 = Workbooks(w2)
    Set ws2 = wb2.Sheets(1)

    '~~> Work with First workbook to get last row and define your range
    With ws1
        lRowW1 = .Range("E" & .Rows.Count).End(xlUp).Row
        Set ws1Rng = .Range("E2:E" & lRowW1)
    End With

    '~~> Work with Second workbook to get last row and define your range
    With ws2
        .Range("A1", "D1").EntireColumn.Hidden = True

        lRowW2 = .Range("E" & .Rows.Count).End(xlUp).Row
        Set ws2Rng = .Range("E2:E" & lRowW2)

        For Each cl In ws2Rng
            '~~> Do the find
            Set acell = ws1Rng.Find(what:=cl.Value, LookIn:=xlValues)

            '~~> Check if found or not. This is required else you will
            '~~> get an error if no match found
            If Not acell Is Nothing Then
                '
                '~~> Do what ever you want here
                '
            End If
        Next
    End With
End Sub