执行 Excel 宏时出现“类型不匹配”错误

Question

我创建了一个宏来从我的 excel 文件中的空行中删除所有边框。这是mig代码：

Sub RemoveRows()
'
' RemoveRows Macro
'

'
    Range("A8").Select

    Dim checkval

    Dim RowAmount
    RowAmount = 93



    Do
        checkval = ActiveCell.Value
        If (checkval = "" Or checkval = Null) Then
            ActiveCell.EntireRow.Delete
        Else
            ActiveCell.Offset(1, 0).Select
        End If
        RowAmount = RowAmount - 1
    Loop While RowAmount > 0


End Sub

运行宏的方法：

public void RemoveRows_Macro(string fileName)
{
    Microsoft.Office.Interop.Excel.Application xlApp = new Microsoft.Office.Interop.Excel.Application();
    Microsoft.Office.Interop.Excel.Workbook xlWorkBook;
    xlWorkBook = xlApp.Workbooks.Open(fileName);
    xlApp.DisplayAlerts = true;

    //Run the macro
    xlApp.Run("RemoveRows", Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing,
        Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing,
        Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing, Type.Missing);

    xlWorkBook.Save();

    xlWorkBook.Close(false);
    xlApp.Quit();
    releaseObject(xlApp);
    releaseObject(xlWorkBook);
}

我的问题是我可以从我的 C# 应用程序运行此宏而不会出现此错误，但是当其他人使用我的 C# 应用程序时会收到此错误：Run-time error '13': Type Mismatch

我做错了什么？

Answer 1

要远离单元格格式，请始终使用Value2。

总是标注变量类型，只在需要的时候使用，checkval不是很有用，你可以直接检查ActiveCell.Value2 = ""或者检查IsEmpty(ActiveCell)。

如果你真的想使用这个变量而不是将其标注为Variant。

Excel 单元格值不为 NULL，它们至少为空或等于空字符串 ("")，因此在 VBA 中执行 IsNull 或 = NULL 检查没有意义。跳过对 Null 的检查，它应该可以正常工作。

Answer 2

试试这个版本

它处理

• 可能的条目显示为为空单元格但不是（删除它们）
• 返回 "" 的公式（离开它们）
• 大大提高了运行时间

---

Sub RemoveRows()
    Dim dat As Variant
    Dim i As Long
    Dim rng As Range, rngDel As Range
    Dim str As String

    Set rng = Range("A8:A100")
    dat = rng.Formula

    For i = 1 To UBound(dat, 1)
        str = Replace$(dat(i, 1), Chr(160), "")
        str = Replace$(str, vbCr, "")
        str = Replace$(str, vbLf, "")
        str = Replace$(str, vbTab, "")
        If Len(Trim$(str)) = 0 Then
            If rngDel Is Nothing Then
                Set rngDel = rng.Cells(i, 1)
            Else
                Set rngDel = Application.Union(rngDel, rng.Cells(i, 1))
            End If
        End If
    Next

    If Not rngDel Is Nothing Then
        rngDel.EntireRow.Delete
    End If

End Sub

Answer 3

有几件事可以尝试：

1. 最好声明变量类型，在本例中为 string 或 variant 或 range。
2. 尝试使用IsNull(checkval) 函数而不是checkval = Null。
   • 正如@Chris 所说，一个单元格确实是Empty 而不是null，使用isempty(a)。
   • 经过一些处理，这似乎是一个常见问题，我遇到了一个看似万无一失的好解决方案，使用 len(trim(a)) = 0 作为检查。
3. 没有必要通过选择单元格来循环访问它们：

代码：

Sub RemoveRows() 
'
' RemoveRows Macro 
'

' 

    Dim checkval as long, RowAmount as long
    checkval = 8
    RowAmount = 93

    Do 

        'If trim(range("A" & checkval)) = "" Or _
        '       isempty(range("A" & checkval)) Then 'thanks chris
        If Len(Trim(range("A" & checkval))) = 0 then 
            range("A" & checkval).EntireRow.Delete 
        Else 
            checkval  = checkval + 1
        End if
        RowAmount = RowAmount - 1 

    Loop While RowAmount > 0

End Sub