用户表单 - VLOOKUP 和表单计算

Question

我有一个包含多个字段的表单。我在表单上有一个字段，我想在其中进行计算。这需要一个辅助列函数的VLOOKUP。

在常规单元格中，我可以输入以下内容：

=VLOOKUP(B3&C3&D3,Ins_Price_Tbl,5,0)

Ins_Price_Tbl 是一个数据表。

并得到我正在寻找的答案。

我的表单有文本框

txtAdjustmentCountYearA - An integer
txtInsurance - A String
txtAdjustmentYearA - A year like 2018
txtAdjustmentCostYearA - The result field

我需要txtAdjustmentCostYearA 来执行VLOOKUP，在这种情况下，C3 将等于“调整”或我输入的任何文本并将其乘以txtAdjustmentCountYearA.Value

所以我可能会有类似的东西：

txtAdjustmentCountYearA.Value 等于 2

txtAdjustmentYearA.Value 等于 2018

txtAdjustmentCostYearA 等于：

=VLOOKUP(Me.txtInsurance.Value&"Whatever I type in here"&Me.txtAdjustmentYearA,Ins_Price_Tbl,5,0) * txtAdjustmentCountYearA.Value

Answer 1

尽可能靠近您的 OP

Option Explicit                             ' declaration head of code module

Private Sub CommandButton1_Click()
Dim ws As Worksheet                         ' provide for range reference
Set ws = ThisWorkbook.Worksheets("MySheet") ' <~~ change to your sheet name
Dim searched As String, found As Variant, factor As Double
searched = Me.txtInsurance.Text & ws.Range("C3").value & Me.txtAdjustmentYearA.Text
' use the Application function VLookup instead of worksheetfunction.VLookup
' allowing to ask a IsError condition (variable found has to be of type Variant!)
  found = Application.VLookup(searched, ws.Range("Ins_Price_Tbl"), 5, 0)
' Textbox values are always strings and have to be converted (e.g. to Double)
  If IsNumeric(txtAdjustmentCountYearA.Text) Then factor = CDbl(txtAdjustmentCountYearA.Text)
' Check possible errors before assigning result to textbox (again as String!)
  If Not IsNumeric(found) Or IsError(found) Then
     Me.txtAdjustmentCostYearA.Text = "Nothing found"
  Else
     Me.txtAdjustmentCostYearA.Text = found * factor
  End If
End Sub