具有无限参数的 UDF

Question

我正在编写一个用户定义函数 (UDF)，它以一些单元格作为参数。 这些单元格包含相同的数据，但精度不同；该函数显示可用的最佳精度。

函数的参数按精度升序写入。

这是一个例子：

+---+-----------------+---------------------+
|   |        A        |          B          |
+---+-----------------+---------------------+
| 1 | Best            | =get_best(B5;B4;B3) |
| 2 |                 |                     |
| 3 | provisional     | 1                   |
| 4 | definitive      | 2                   |
| 5 | etched in stone | 12                  |
+---+-----------------+---------------------+

函数显示 12，因为单元格 B5 中的信息比 B4 和 B3 具有更好的价值。因此，在公式参数中，B5 写在 B4 和 B3 之前。

我的UDF代码如下：

Public Function get_best(r1 As Range, r2 As Range, r3 As Range) As Variant

    get_best = ""

    If r3.Value <> "" Then get_best = r3.Value Else
    If r2.Value <> "" Then get_best = r2.Value Else
    If r1.Value <> "" Then get_best = r1.Value

End Function

有效！但我想对其进行编辑，以便它可以像=get_best(B7;B6;B5;B4;B3) 那样进行无限量的调整。 我怎么能这样做？

有用的评论： “单元格 B5 比 B4 和 B3 具有更好的值”意味着，例如，在 B3 中，您有 12 个月前计算的预测值。在单元格 B5 中，您有有效值和测量值。因此，当您拥有 B5 时，您不再需要 B3，因为“B5 比 B3 更好”

Answer 1

如果 best 值始终位于 Range 的底部，但您不确定要搜索的列中的行数，则可以使用：

Public Function get_best(rng As Range) As Variant

    Dim lngLastRow As Long

    lngLastRow = rng.Parent.Cells(rng.Parent.Rows.Count, rng.Column).End(xlUp).Row
    get_best = rng.Parent.Cells(lngLastRow, rng.Column).Value

End Function

Answer 2

根据您展示的示例，这对您不起作用吗？

Public Function get_best(ByVal Rng As Range) As Variant
    get_best = Application.Max(Rng)
End Function

那你可以这样试试……

=get_best(B3:B5)

Answer 3

我不明白您所说的 “单元格 B5 比 B4 和 B3 具有更好的价值”是什么意思。您的代码会查看哪个单元格包含从参数中最后一个开始的值。

您可以使用参数数组添加任意数量的范围：

Public Function get_best(ParamArray Ranges()) As Variant

    Dim x As Long

    For x = UBound(Ranges) To LBound(Ranges) Step -1
        If Ranges(x) <> "" Then
            get_best = Ranges(x).Value
            Exit For
        End If
    Next x

End Function

Answer 4

您可以避免以这种方式传递任何range 参数

Public Function get_best() As Variant
    get_best = Cells(Rows.Count, Application.Caller.Column).End(xlUp).Value
End Function

如果你必须指定一个（连续的）范围，你可以如下操作：

Public Function get_best(r As Range) As Variant
    With r
        If WorksheetFunction.CountA(.Cells) > 0 Then get_best = .Cells(.Rows.Count + 1).End(xlUp).Value
    End With
End Function