如何计算一个值在不同文件中重复的次数？

Question

我想知道一个值被重复的次数，例如 288，以及在许多具有相同格式的文件中总共有多少个值（每个数字）。

对于一个工作表，我只会使用 =COUNTIF(F:F;288) 和 =COUNTA(F:F)

但现在我必须在一个文件夹中处理超过 30000 个 xlsx 文件。

我的第一个意图是将它们合并到一个文件 like this 然后用 this solution 计数，但它在 5279 个标签后停止，我猜是某种限制。

我的所有文件都在同一个文件夹 (H:\Macro\positions) 中，并且这些值只在 F 列中。

每个文件有 100-600 个值，大约 30000 个文件。

操作只需完成一次，我不介意等待几个小时才能完成。

你会怎么做？

Answer 1

尝试下面的代码并遵循 cmets - 基本上，该代码会打开给定文件夹中的每个电子表格，循环浏览该工作簿中的工作表，为每个工作表运行 COUNTIF 公式并记录总数。

Option Explicit

Sub CheckForValue()

    Dim objFso As FileSystemObject '<-- add Microsoft Scripting Runtime as a reference
    Dim objFile As File
    Dim wbToCheck As Workbook
    Dim wsToCheck As Worksheet
    Dim strPath As String
    Dim varValue As Variant
    Dim lngValueCount As Long
    Dim lngTotal As Long
    Dim wsf As WorksheetFunction

    On Error Goto CleanUp

    strPath = "H:\Macro\positions"
    Set objFso = New FileSystemObject '<-- access to file system
    varValue = 288 '<-- value you are looking for
    lngTotal = 0 '<-- total count of value you are looking for
    Set wsf = Application.WorksheetFunction '<-- shortcut to WorksheetFunction

    ' iterate files in folder
    For Each objFile In objFso.GetFolder(strPath).Files
        ' only check spreadsheets
        If objFile.Type = "Microsoft Excel Worksheet" Then
            ' get reference to workbook
            Set wbToCheck = Workbooks.Open(objFile.Path)
            ' iterate worksheets
            For Each wsToCheck In wbToCheck.Worksheets
                ' your original formula
                lngValueCount = wsf.CountIf(wsToCheck.Range("F:F"), varValue)
                ' add to total
                lngTotal = lngTotal + lngValueCount
            Next wsToCheck
            ' close without saving changes
            wbToCheck.Close SaveChanges:=False
        End If
    Next objFile

    ' final count of value you are looking for
    Debug.Print "Total is: " & lngTotal

CleanUp:
    ' error handling
    If Err.Number <> 0 Then
        Debug.Print Err.Description
    End If

    Set objFile = Nothing
    Set objFso = Nothing

End Sub

根据您的评论，该操作必须只执行一次，我不介意等待几个小时才能完成然后上面的代码会做到这一点，只需仔细检查工作表价值。如果你想提高速度，可以在For循环之前使用以下代码来帮助：

Application.ScreenUpdating = False
Application.DisplayAlerts = False
Application.EnableEvents = False

然后将设置转回（在CleanUp: 语句之后）：

Application.ScreenUpdating = True
Application.DisplayAlerts = True
Application.EnableEvents = True