为什么红灯不亮？

Question

所以我对这个 IOT 的东西非常陌生，我在这里尝试创建的内容有点像交通违规，我的想法是当红灯亮起并且 PIR 传感器检测到蜂鸣器/LED 变高的那一刻。

图片如下：

代码如下所示

int pir = 2;
int rojo = 12; 
int amarillo = 11;
int verde = 10;
int led = 7;

void setup()
{
  pinMode(pir, INPUT);
  pinMode(led, OUTPUT);
  Serial.begin(9600);
  pinMode(verde, OUTPUT); //It declares the green pin as output 
  pinMode(amarillo, OUTPUT);//It declares the yellow pin as output 
  pinMode(rojo, OUTPUT);
}
    
void loop()
{
  digitalWrite(verde, HIGH); //It turns on the green led 
  delay(15000); //wait 15 seconds 
  digitalWrite(verde, LOW); //It turns off the green led 
  delay(250); //wait 0.25 seconds
  
  digitalWrite(amarillo, HIGH); //It turns on the yellow led 
  delay(3000); //wait 3 seconds 
  digitalWrite(amarillo, LOW); //It turns off the yellow led 
  delay(250); //wait 0.25 seconds
  int val = digitalRead(pir);
  Serial.println(val);
    
  digitalWrite(rojo, HIGH); //It turns on the red led 
  delay(15000); //wait 15 seconds 
  digitalWrite(rojo, LOW);
  if (rojo == HIGH) {
    if (val == HIGH) {
      digitalWrite(led, HIGH);
    } else {
      digitalWrite(led, LOW); 
    }
    delay(10);
  }
}

Answer 1

问题出在这里：

  digitalWrite(rojo, HIGH); //It turns on the red led 
  delay(15000); //wait 15 seconds 
  digitalWrite(rojo, LOW);
  if (rojo == HIGH) {
    if (val == HIGH) {
      digitalWrite(led, HIGH);
    } else {
      digitalWrite(led, LOW); 
    }
    delay(10);
  }

首先，rojo 是一个 pin 号，而不是您要在此比较中使用的值。

其次，在您的延迟delay(15000) 期间，代码停止运行，因此在此期间未检测到移动。

在 15 秒延迟期间检测的唯一方法是使用 millis() 作为您的时间和延迟（或使用中断）。

你可以尝试这样的事情（未经测试）：

digitalWrite(rojo, HIGH); //It turns on the red led 
unsigned long int redStartTime = millis();
while (millis() - redStartTime <= 15000) {
  delay(100);
  int val = digitalRead(pir);
  if (val == HIGH) {
    digitalWrite(led, HIGH);
  } else {
    digitalWrite(led, LOW); 
  }
}
digitalWrite(rojo, LOW);

我没有对此进行测试，但我希望你能明白。

请注意，我不知道运动检测器在某物移动时返回HIGH 还是LOW；您可能需要更改那里的代码。

Answer 2

你需要改变你的 if 的位置

int pir=2;
int rojo=12; 
int amarillo=11;
int verde=10;
int led=7;

void setup()
{
    pinMode(pir,INPUT);
    pinMode(led,OUTPUT);
    Serial.begin(9600);
    pinMode(verde,OUTPUT); //It declares the green pin as output 
    pinMode(amarillo,OUTPUT);//It declares the yellow pin as output 
    pinMode(rojo,OUTPUT);
}
    
void loop()
{
    digitalWrite(verde,HIGH); //It turns on the green led 
    delay(15000); //wait 15 seconds 
    digitalWrite(verde,LOW); //It turns off the green led 
    delay(250); //wait 0.25 seconds
    
    digitalWrite(amarillo,HIGH); //It turns on the yellow led 
    delay(3000); //wait 3 seconds 
    digitalWrite(amarillo,LOW); //It turns off the yellow led 
    delay(250); //wait 0.25 seconds
    int val = digitalRead(pir);
    Serial.println(val);
    
    digitalWrite(rojo,HIGH); //It turns the red led 
    if(val==HIGH){             //---> //I dont know if this value can be compared with HIGH, on my programm whe costum use numbers!
        digitalWrite(led,HIGH);
    }
    else{
        digitalWrite(led,LOW); 
    }
    delay(15000); //wait 15 seconds 
    digitalWrite(rojo,LOW);
    delay(10);
}