SQL 2000 TSQL - 创建数据透视表

Question

我真的很想弄清楚如何将 MS Access CrossTab 查询转换为 T-SQL 以在 SQL2000 上运行或转换为 Linq-to-SQL。我有一个在 Access 中看起来像这样的查询：

并产生这个：

查询基本上按 ItemID 和 StoreID 分组，并对销售的数量求和，但使用 Access 中的 CrossTab 查询，我可以为每一行设置一个唯一的 ItemID，为每个 StoreID 设置一个列，以及每个 StoreID 的总数量/ItemID 组合作为值。

如何在 T-SQL 2000 中构造它？我可以使用分组构建一个简单的选择查询，但它提供了三列中的数据，StoreID、ItemID 和 Qty。但我需要的是 ItemID 的列和结果集中每个 StoreID 的列

SELECT     Trans.TranSID as StoreID, TransDetail.TranItemID as ItemID, SUM(TransDetail.Qty) AS TotalQtyForStore
    FROM         Trans INNER JOIN
                          TransDetail ON Trans.TranID = TransDetail.TranID INNER JOIN
                          Item ON TransDetail.TranItemID = Item.ItemID
    WHERE     (Trans.TranDate > CONVERT(DATETIME, '2005-01-01 00:00:00', 102)) AND (Trans.TranTypeID = 'so' OR
                          Trans.TranTypeID = 'ca') AND (Trans.TranStatus <> 'v') AND (Item.ItemClassID = 'RHM')
    GROUP BY Trans.TranSID, TransDetail.TranItemID

产生这个：

但我真正需要做的是转换这些数据，使 StoreID 值变成列，就像上面的 Access CrossTab 查询一样。

Answer 1

我会使用动态 SQL 来执行此操作，因为您可能事先不知道所有存储 (TranSID) 值。此存储过程将开始/结束日期作为参数，并生成一个交叉表。您可能还可以参数化其他一些东西，例如 TranStatus 和 ItemClassID，但不清楚它们是查询中的固定元素还是可变元素。

CREATE PROCEDURE dbo.CrossTabByItem
  @StartDate DATETIME,
  @EndDate   DATETIME = NULL
AS
BEGIN
  SET NOCOUNT ON;

  SET @EndDate = COALESCE(DATEADD(DAY, 1, @EndDate), GETDATE());

  DECLARE @sql NVARCHAR(4000); SET @sql = N'';

  SELECT @sql = @sql + ',
    [' + TranSID + '] = SUM(CASE WHEN t.TranSID = ''' 
    + TranSID + ''' THEN td.Qty ELSE 0 END)' FROM 
    (
      SELECT DISTINCT TranSID FROM dbo.Trans
      WHERE TranDate >= @StartDate AND TranDate < @EndDate
    ) AS x ORDER BY TranSID;

    SET @sql = N'SELECT ItemID = td.TranItemID' + @sql + '
      FROM dbo.Trans AS t
      INNER JOIN dbo.TransDetail AS td
       ON t.TranID = td.TranID
      INNER JOIN dbo.Item AS i
       ON td.TranItemID = i.ItemID
      WHERE t.TranDate >= @StartDate
      AND t.TranDate < @EndDate
      AND t.TranTypeID IN (''so'',''ca'')
      AND t.TranStatus <> ''v''
      AND i.ItemClassID = ''RHM''
      GROUP BY td.TranItemID;';

    EXEC sp_executesql @sql, 
      N'@StartDate DATETIME, @EndDate DATETIME', 
      @StartDate, @EndDate;
END
GO

所以你可以这样称呼它，以获取从 2005 年 1 月 1 日到现在的所有内容：

EXEC dbo.CrossTabByItem @StartDate = '20050101';

或者像这样，得到 2005 年 1 月：

EXEC dbo.CrossTabByItem @StartDate = '20050101', @EndDate = '20050131';