VBA：将超链接从单元格分配到对象

Question

我的仪表板已锁定，因此同事不能意外更改/删除任何内容。

不过，我需要他们能够向按钮添加超链接。

我创建了一个“设置”表，允许他们输入信息，然后这些信息将反映在仪表板上（KPI、标题等）。我希望它包含一个按钮，该按钮会将“设置”上的 B5 的超链接分配给仪表板上的按钮（名为“CoverageButton”）。

这是设置表，使用 Google 作为替代链接：

我尝试使用的代码是：

Sub AssignURL()

Dim fileLink As String

Application.ScreenUpdating = False

With ActiveWorkbook

fileLink = Cells(5, 2) 'indicating where link is
    .Hyperlinks.Add Anchor:=.Shapes("CoverageButton"), _
    Address:=fileLink

End With

Application.ScreenUpdating = True

End Sub

我收到运行时错误“438”对象不支持此属性或方法，突出显示以.Hyperlinks 开头的行。使用 2016 版 Excel。

我错过了什么吗？

Answer 1

Shapes 是工作表的属性，而不是工作簿。

另外，您没有正确限定单元格。

Sub AssignURL()
Dim fileLink As String

    Application.ScreenUpdating = False

    ' add link to 'CoverageButton' on 'Dashboard' sheet
    With ActiveSheet
        fileLink = .Cells(5, 2)                  
        .Hyperlinks.Add Anchor:=.Shapes("CoverageButton"), _
        Address:=fileLink
    End With

    Application.ScreenUpdating = True

End Sub

注意，如果按钮位于不同的工作表上，您可能希望使用类似这样的内容，我们明确引用 Set Up 和 Dashboard 工作表。

Sub AssignURL()
Dim fileLink As String

    Application.ScreenUpdating = False

    ' get link from 'Set Up' sheet
    fileLink = Sheets("Set Up").Cells(5, 2).Value

    With Sheets("Dashboard")
        .Hyperlinks.Add Anchor:=.Shapes("CoverageButton"), _
        Address:=fileLink
    End With

    Application.ScreenUpdating = True

End Sub