将 OnChange 事件添加到动态创建的 vba 表单控件

Question

我在 excel 中有一个表单，我需要在其中动态创建组合框和列表框。所以，这个想法是，每个列表框都链接到组合框。第一个默认设置，如果用户需要添加另一个组合+列表框，可以按“添加”按钮。所以“添加”按钮的代码如下：

Private Sub AddCountry_Click()
aaa = "a"
Set comb = Controls.Add("Forms.Combobox.1", "CountryList" & Val(CountryLabel.Caption) + 1)
With comb
.Top = CountryList1.Top
.Width = CountryList1.Width
.Height = CountryList1.Height
.Left = (CountryList1.Width + 3) * Val(CountryLabel.Caption) + CountryList1.Left
.AddItem ("--Choose country--")
For i = 3 To 20
.AddItem Worksheets("Countries").Range("B" & i).Value
Next i
.Text = "--Choose country--"
End With

Set listb = Controls.Add("Forms.Listbox.1", "Countries" & Val(CountryLabel.Caption) + 1)
With listb
.Top = Countries1.Top
.Width = Countries1.Width
.Height = Countries1.Height
.Left = (Countries1.Width + 3) * Val(CountryLabel.Caption) + Countries1.Left
.ColumnCount = 2
.MultiSelect = 1
End With
CountryLabel.Caption = Val(CountryLabel.Caption) + 1
End Sub

这个想法是，组合框必须有名称“CountryList”和一个数字，存储在不可见标签中（每次按下按钮时都会添加 +1），所以它将是 CountryList1、CountryList2 等. 列表框也是如此。

所以事情是这样的，组合框和值（国家名称）被正确添加。但是我没搞定，以后怎么用呢？我需要的是 - 当组合框发生变化时（用户选择不同的国家），下面的列表框必须填充某些值（每个国家不同）。

我认为，问题可能在于定义组合/列表框的名称。那么是否可以添加动态名称（CountryList1、CountryList2 等），然后以某种方式添加 OnChange 事件？提前致谢。

Answer 1

这是 ComboBox 的示例。你可以基于它的列表框，因为原理是完全一样的。

首先创建一个名为 cComboBox 的类并将这段代码放入其中：

Private WithEvents p_ComboBoxEvents As MSForms.ComboBox
Private Sub p_ComboBoxEvents_Change()
    'Here you can handle the events.
End Sub
Public Property Let Box(value As MSForms.ComboBox)
    Set p_ComboBoxEvents = value
End Property
Public Property Get Box() As MSForms.ComboBox
    Set Box= p_ComboBoxEvents
End Property

接下来，在您现有的代码中，您可以添加此 cComboBox 并放置您已添加的 Combobox：

'Add the custom box!
Private customBox as cComboBox
Private Sub AddCountry_Click()
    aaa = "a"
    Set comb = Controls.Add("Forms.Combobox.1", "CountryList" & Val(CountryLabel.Caption) + 1)

    With comb
        .Top = CountryList1.Top
        .Width = CountryList1.Width
        .Height = CountryList1.Height
        .Left = (CountryList1.Width + 3) * Val(CountryLabel.Caption) + CountryList1.Left
        .AddItem ("--Choose country--")
        For i = 3 To 20
            .AddItem Worksheets("Countries").Range("B" & i).Value
        Next i
        .Text = "--Choose country--"
    End With

Set customBox = New cComboBox
customBox.Box = comb

End Sub

当然，您可能想要创建一个包含这些元素的数组，这样您就可以拥有任意数量的元素，而不管它们是如何命名的。但是：您会看到，如果您更改添加的 ComboBox 值，p_ComboBoxEvents_Change 将触发。