Bash 在两个字符串之间打印文件内容

Question

a
b
s
start
text
more text
end
even more text
end

我想打印start 和start 之后的第一个end 之间的内容（start 始终是唯一的）。我还想在打印文本的行之间打印，在本例中是在第 4 行和第 7 行之间。

我正在尝试使用grep 和cat，但我做不了什么。

我试过了：

var=$(cat $path)
echo "$var" | grep -o -P '(?<=start).*(?=end)'

但它没有打印任何内容，没有grep，它会打印整个文件。

这个例子中的输出应该是：

The content is between lines 4 and 7.

start
text
more text
end

Answer 1

将shell变量传递给awk，然后按范围打印文本，然后尝试，在awk的start变量中提及你的shell变量，那么我们应该很好。 （也可以将 $0 ~ start 更改为 $0 ~ "^"start"$"，以防您想在行中查找起始值的完全匹配。）

awk -v start="$your_shell_start_var" '
$0 ~ start,$0 ~ /^end$/{
  print
  if($0 ~ start){ startLine=FNR }
  if($0~/^end$/){ 
     print "The content is between lines " startLine " and " FNR
     exit
  }
}' Input_file

OP 样本的样本输出：

start
text
more text
end
The content is between lines 4 and 7

简单解释： 在此语句之间按范围打印行 start 到 end 检查条件是否行有结束字符串然后从 Input_file 中出来，我们不需要读取完整的 Input_file，因为 OP 只需要打印第一组行。

Answer 2

样本数据：

$ cat -n strings.dat
 1  a
 2  b
 3  s
 4  start
 5  text
 6  more text
 7  end of more text
 8  end
 9  even more text
10  end

一个awk 解决方案使用一个范围（类似于 RavinderSingh13 的帖子），在末尾打印出 OP 的文本消息：

startstring="start"                            # define start of search block

awk -v ss="${startstring}" '                   # pass start of search block in as awk variable "ss"

# search for a range of lines between "ss" and "end":

$0==ss,/^end$/ { if ($0==ss && x==0 ) x=FNR    # if this is the first line of the range make note of the line number
                 print                         # print the current line of the range
                 if ($0=="end")                # if this is the last line of the range then print our textual message re: start/finish line numbers
                    printf "\nThe content is between lines %d and %d.\n",x,FNR
               }
' strings.dat

注意：$0==ss 和 /^end$/ 测试假定数据文件中没有前导/尾随空格，否则这些测试将失败并且没有范围匹配。

使用startstring="start" 会生成：

start
text
more text
end of more text
end

The content is between lines 4 and 8.

使用startstring="more text" 会生成：

more text
end of more text
end

The content is between lines 6 and 8.

使用startstring="even more text" 会生成：

even more text
end

The content is between lines 9 and 10.

使用startstring="water" 会生成：

--no output--

注意：如果 OP 使用startstring="end"，结果与预期不符；虽然可以添加更多代码来解决这种情况，但我将暂时跳过这种情况。