如何检查一个文件中的一个数字范围是否是另一个文件中其他数字范围的子集？

Question

我试图找出 range1 的数字 [a 和 b 列] 是子集还是位于 range2 的列 [b 和 c 列] 之间。

范围1

a        b
15       20
 8       10
37       44
32       37

范围2

    a       b       c
    chr1    6       12
    chr2    13      21
    chr3    31      35
    chr4    36      45

输出：

a       b       c
chr1    6       12       8       10
chr2    13      21       15      20
chr4    36      45       37      44

我想比较 range1[a] 和 range2[b] 以及 range1[b] 和 range2[c]。一对一比较。

例如在第一次运行中：range-1 的第一行与 range-2 的所有其他行。但是 range1[a] 应该只与 range2[b] 比较，同样，range1[b] 应该只与 range2[c] 比较。基于此，我只写了一个标准：

lbs[i] && lbsf1[j] <= ubs[i] && ubsf1[j] >= lbs[i] && ubsf1[j] <= ubs[i]

r1[a] r2[b] r1[b] r2[c]
15 > 6      20 < 12     False
15 > 13     20 < 21     True
15 > 31     20 < 35     False
15 > 36     20 < 45     False 

我试图从这段代码中学习[如果我们想检查一个数字是否在特定范围内，它是有效的]，因此我尝试为两个数字修改相同的值。但是没有用，我觉得我无法正确读取第二个文件。

代码：[参考但稍作修改]

    #!/bin/bash

awk -F'\t' '
# 1st pass (fileB): read the lower and upper range bounds
FNR==NR { lbs[++count] = $2+0; ubs[count] = $3+0; next }
# 2nd pass (fileA): check each line against all ranges.
{ lbsf1[++countf1] = $1+0; ubsf1[countf1] = $2+0;

        for(i=1;i<=count;++i)
                {
                        for(j=1;j<=countf1;++j)
                        {
                        if (lbsf1[j] >= lbs[i] && lbsf1[j] <= ubs[i] && ubsf1[j] >= lbs[i] && ubsf1[j] <= ubs[i])
                                { print lbs[i]"\t"ubs[i]"\t"lbsf1[j]"\t"ubsf1[j] ; next }
                        }
                }
}
' range2 range1

这段代码给了我输出：

6       12      8       10
6       12      8       10
6       12      8       10

谢谢。

Answer 1

假设：

• 输入文件没有a b或a b c作为第一行（如果这些行确实存在于数据中，我们可以修改建议的代码）
• range2 中的行没有前导空格（如提供的示例所示）
• 虽然提供的小样本没有证明，但假设range1 中的一行可能与range2 中的多行“匹配”并且我们想要打印所有匹配项（如果我们可以修改建议的代码一旦我们找到第一个“匹配”，需要停止处理range1 行）

样本数据：

$ cat range1
15      20
 8      10
37      44
32      37

$ cat range2
chr1    6       12
chr2    13      21
chr3    31      35
chr4    36      45
chr15   36      67             # added to demonstrate multi-match for range1 [ 37 , 44 ]

当前代码的问题：

• 将range1 数据加载到一个数组中，然后为从range1 读取的每一行循环遍历这个（不断增长的数组）；这个数组是不必要的，因为我们只需要处理来自range1 的 current 行
• 在打印第一个匹配的记录集时，双循环逻辑被中止（; next）；这种过早的取消意味着我们只能看到第一场比赛……一遍又一遍； ; next 可以删除
• range2[a] 列在 range2 输入处理期间未捕获，因此我们无法在最终输出中显示此列

更新 OP 的当前代码以解决这些问题：

awk '
BEGIN   { FS=OFS="\t" }

FNR==NR { chromo[++count]=$1
          lbs[count]=$2
          ubs[count]=$3
          next
        }

        { lb=$1
          ub=$2

          for (i=1;i<=count;++i)
              if ( lb >= lbs[i] && lb <= ubs[i] && ub >= lbs[i] && ub <= ubs[i] )
                 print chromo[i],lbs[i],ubs[i],lb,ub
        }
' range2 range1

这会生成：

chr2    13      21      15      20
chr1    6       12       8      10
chr4    36      45      37      44
chr15   36      67      37      44

如果需要对输出进行排序，我们可以修改awk 代码以将结果存储在另一个数组中，然后在END {...} 处理期间排序并打印该数组。但为简单起见，我们只需将输出通过管道传输到sort，例如：

$ awk ' BEGIN { FS=OFS="\t" } FNR==NR ....' range2 range1 | sort -V
chr1    6       12       8      10
chr2    13      21      15      20
chr4    36      45      37      44
chr15   36      67      37      44