/start/,/end/ 范围表达式在 awk 中有用吗？

Question

我一直认为你不应该使用这样的范围表达式：

/start/,/end/

在 awk 中，因为尽管它使您只想打印匹配文本（包括开始行和结束行）的情况比替代方案略短*：

/start/{f=1} f{print; if (/end/) f=0}

当您想要稍微调整它以执行其他任何操作时，它需要完全重写或导致重复或其他不受欢迎的代码。例如如果您想使用上面的第二种形式打印不包括范围分隔符的匹配文本，您只需调整它以移动组件：

f{if (/end/) f=0; else print} /start/{f=1}

但如果您从 /start/,/end/ 开始，则需要放弃这种方法，转而支持我刚刚发布的内容，否则您必须编写如下内容：

/start/,/end/{ if (!/start|end/) print }

即复制不需要的条件。

然后我看到一个问题发布，需要识别文件中的 LAST end 以及解决方案中使用范围表达式的位置，我认为这似乎有一些价值（请参阅 https://stackoverflow.com/a/21145009/1745001）。

不过，现在，我又开始思考，完全不值得为范围表达式烦恼，而不使用范围表达式的解决方案同样适用于这种情况。

那么 - 有没有人举例说明范围表达式实际上为解决方案增加了显着的价值？

*我曾经使用过：

/start/{f=1} f; /end/{f=0}

但太多次我发现当f 为真并且/end/ 被发现时我必须做一些额外的事情（或者换句话说，只有在/end/ 被发现时才做某事如果f 是真的）所以现在我只是尝试坚持稍微不那么简短但更健壮和可扩展的：

/start/{f=1} f{print; if (/end/) f=0}

Answer 1

有趣。我也经常从范围表达式开始，然后切换到使用变量..

我认为除了纯范围的情况之外，这可能有用的情况是，如果您想打印匹配项，但前提是它位于某个范围内。也因为它的作用很明显。例如：

awk '/start/,/end/{if(/ppp/)print}' file

使用此输入：

start
dfgd gd
ppp 1
gfdg
fd gfd
end
ppp 2 
ppp 3
start
ppp 4
ppp 5
end
ppp 6
ppp 7
gfdgdgd

将产生：

ppp 1
ppp 4
ppp 5

-- 当然也可以使用：

awk '/start/{f=1} /ppp/ && f; /end/{f=0}' file

但它更长，可读性稍差..

Answer 2

虽然/start/,/end/ 范围表达式可以很容易地用条件重新实现是对的，但它有许多单独使用的有趣用例。正如您所观察到的，它可能对处理表格数据没有什么价值，这是 awk 的主要但不仅是用例。

那么 - 有没有人举例说明范围表达式实际上为解决方案增加了显着的价值？

在上述用例中，范围表达式提高了易读性。以下是一些示例，其中范围表达式准确地选择了要处理的文本。这些只是示例的一部分，但有无数类似的应用程序，展示了 awk 令人难以置信的多功能性。

过滤某个时间范围内的日志

假设每个日志行都以 ISO 时间戳开头，下面的过滤器会选择给定 1 小时范围内的所有事件：

awk '/^2015-06-30T12:00:00Z/,/^2015-06-30T13:00:00Z/'

从文件中提取文档

awk '/---- begin file.data ----/,/---- end file.data ----/'

这可用于将资源与 shell 脚本捆绑在一起（使用 cat），提取 GPG 签名消息的一部分（使用 --clearsign 准备）或更一般的 MIME 消息。

处理 LaTeX 文件

范围模式可用于匹配 LaTeX 环境，因此例如我们可以选择目录中所有文章的摘要：

awk '/begin{abstract}/,/end{abstract}/' *.tex

或所有定理，准备一个定理数据库！

awk '/begin{theorem}/,/end{theorem}/' *.tex

或编写一个 linter 确保定理不包含引用（如果我们认为这是不好的风格）：

awk '
  /begin{theorem}/,/end{theorem}/ { if(/\\cite{/) { c+= 1 } }
  END { printf("There were %d bad-style citations.\n", c) }
'

或预处理表，等