使用 AWK 进行部分字符串匹配

Question

大家早上好！

我在 file.txt 中有以下几行：

big bird|Big birds tend to be big.;;They have wings.
big truck|I love big trucks!;;Ford makes nice big trucks. 
red truck|Red is my favorite color.;;Red is also a name.

我的两个分隔符是竖线 (|) 和双分号 (;;)。我的脚本接受一个输入，将其与管道 (|) 之前的 file.txt 中的一行匹配，并在由 (;;) 分隔的管道之后随机返回相应的输出。

read -p " " query
response="$(awk -F\| -v r="$query" '$1==r{print $2;exit}' file.txt | sed 's/;;/\n/g' | shuf -n1)"
echo "$response"

例子：

Input: big truck
Output: Ford makes nice big trucks.

但这不起作用，除非输入完全匹配。如何修改 awk 表达式以允许它接受部分匹配或在两个单词倒置的情况下？ （例如“大卡车”而不是“大卡车”

匹配“大”和“卡车”并从线路返回随机输出的期望行为：

Input: some trucks are big
Output: Ford makes nice big trucks.

提前非常感谢！

Answer 1

不清楚您是否需要正则表达式或字符串匹配，也不清楚您是否想要对整个 $1 或 $1 中的“单词”的一部分或 $1 中的整个单词或其他内容进行部分匹配。以下将对 $1 的部分进行全字字符串匹配，因为在我看来这是您最有可能要求的。您也没有说明您希望如何处理输入或查询字符串中的重复项，以便以下匹配唯一单词（例如，与计算单词的出现次数相反）：

$ cat tst.sh
#!/usr/bin/env bash

read -p " " query

response="$(
    awk -v query="$query" '
        BEGIN {
            split(query,tmp)
            for (i in tmp) {
                targets[tmp[i]]
            }

            for (word in targets) {
                targetCnt++
            }

            FS = "[|]"
        }
        {
            delete present
            split($1,tmp," ")
            for (i in tmp) {
                present[tmp[i]]
            }

            matchCnt = 0
            for (word in targets) {
                if (word in present) {
                    matchCnt++
                }
            }

            if ( targetCnt == matchCnt ) {
                sub(/.*;;/,"")
                print
            }
        }
    ' file |
    shuf |
    head -1
)"

printf '%s\n' "$response"

.

$ ./tst.sh
 truck
Red is also a name.
$ ./tst.sh
 truck
Ford makes nice big trucks.
$ ./tst.sh
 truck big
Ford makes nice big trucks.
$ ./tst.sh
 truck big
Ford makes nice big trucks.

Answer 2

脚本'do.awk'：

BEGIN{
        split(input,s," ");
        for (i in s) s2[s[i]]=i;
        srand();
}
{
        split($1,a," ");
        m=0;
        for(i in a) {
                if (a[i] in s2) then m++;
        }
        # add if words match (m>0), first matchcount, then $2
        if (m>0) {
                r[z++]=m";;"$2
                }
}
END {
        # sort array r, last line will have highest matchcount
        n = asort(r);
        # print last value
        # print r[n];
        # get random piece, but exclude r2[1], because it is matchcount.
        x=split(r[n],r2,";;")-1;
        x = int(rand()*x);
        print  r2[x+2];
}

awk -v input="big red" -F\| -f do.awk file.txt 将输出“红色也是一个名字”或“红色是我最喜欢的颜色”

我用来自 awk 的函数 rand() 替换了您使用 shuf 的随机函数。 （我希望它足够随机）。

编辑： 我注意到你在这里有另一篇关于 RANDOM 的帖子：BASH - Regex match line in file.txt with more than one delimiter

编辑2： 多行的匹配计数可以相同。如果这是真的，我们应该添加所有文本，然后随机选择一个。

我将END部分更改如下：

END {
        # sort array r, last line(s) will have highest matchcount
        n = asort(r);
        split(r[n],t,";;");
        m = t[1];
        # add all textx with matchcount=m
        o="";
        for(i=length(r); i>=1; i--) {
                split(r[i],t,";;")
                if(t[1]==m) {
                        for (j=2; j<=length(t); j++) {
                                o=o";;"t[j];
                        }
                } else {
                        break;
                }
        }

        # get random piece, from o.
        x=split(o,r2,";;")-1;
        m=r2[1];
        x = int(rand()*x);
        print  r2[x+2];
}

编辑： 最后我应该提到asort() 仅在 gawk 中可用。