修改子进程的输出以添加时间戳

Question

我有一个分叉子进程的 perl 脚本。

sub my_exec{
    my($args,$stdout, $stderr) = @_;
    my $processes = fork();
    die("Cant fork") unless defined($processes);
    if(processes == 0){
        if(defined $stdout){
            close(STDOUT);
            open STDOUT, $stdout;
        }
        if(defined $stderr){
            close(STDERR);
            open STDERR, $stderr;
        }
        exec @$args;
    }else{
                ...
    }
}

我的主要问题是我想为 stderr 的每一行输出添加一个时间戳。我想知道是否可以在这里完成。如您所见，stderr 并不总是改变。我假设我可以通过某种管道来做到这一点？我还想重定向父脚本（同时将 stdout 和 stderr 重定向到文件的守护程序）以使用时间戳。

谢谢

Answer 1

假设你写my_exec如下。

sub my_exec {
  my($args,$stdout,$stderr) = @_;  # caller untaints

  open my $oldout, ">&STDOUT" or die "$0: save STDOUT: $!";

  my $pid = open my $pipe, "-|" // die "$0: fork: $!";
  if ($pid) {
    if (defined $stderr) {
      open STDERR, ">", $stderr or die "$0: open: $!";
    }
    while (<$pipe>) {
      print STDERR scalar(localtime), ": ", $_;
    }
    close $pipe or die $! ? "$0: error closing $args->[0] pipe: $!"
                          : "$0: exit status " . ($? >> 8) . " from $args->[0]";
  }
  else {
    open STDERR, ">&STDOUT"    or die "$0: pipe STDERR: $!";
    if (defined $stdout) {
      open STDOUT, ">", $stdout or die "$0: open: $!";
    }
    else {
      open STDOUT, ">&", $oldout or die "$0: restore STDOUT: $!";
    }
    exec @$args or die "$0: exec @$args: $!";
  }
}

重点在documentation on open中描述：

如果您在命令 - 上打开管道（即，使用 open 的一个或两个参数形式指定 |- 或 -|），则完成隐式 fork，因此 open返回两次：在父进程中返回子进程的 pid，在子进程中返回（已定义）0。使用defined($pid)或//判断打开是否成功。

隐式fork的重点是在父进程和子进程之间建立管道。

父进程的文件句柄表现正常，但该文件句柄的 I/O 是从子进程的STDOUT 管道传输的。在子进程中，文件句柄没有打开——I/O 来自新的STDOUT。

这几乎是完美的，除了你想修改标准错误，而不是标准输出。

这意味着我们需要保存父母的STDOUT，以便孩子可以恢复它。这就是 $oldout 正在发生的事情。

将子级的（重定向的）STDOUT 复制到其STDERR 上可以安排底层守护程序的标准错误通过管道运行，父级读取、修改和输出管道。

一个有点棘手的地方是处理重定向的地方。如果调用者想要重定向STDOUT，这需要在孩子身上发生。但是要重定向STDERR，父级需要这样做，因为这给了父级修改流的机会。

完整示例的代码如下所示。你提到了一个守护进程，所以我启用了Perl’s dataflow analysis known as taint mode。

#! /usr/bin/perl -T

use strict;
use warnings;

use v5.10.0;  # for defined-or //

$ENV{PATH} = "/bin:/usr/bin";

sub my_exec {
  # paste code above
}

#my_exec ["./mydaemon"];
#my_exec ["./mydaemon"], "my-stdout";
my_exec ["./mydaemon"], "my-stdout", "my-stderr";

用一个简单的mydaemon的

#! /usr/bin/env perl

print "Hello world!\n";
warn  "This is a warning.\n";
die   "All done.\n";

输出到单独的文件。

1. my-stdout:

世界你好！

2。 my-stderr:

2013 年 11 月 5 日星期二 17:58:20：这是一个警告。
2013 年 11 月 5 日星期二 17:58:20：全部完成。
./wrapper：在 ./wrapper 第 23 行从 ./mydaemon 退出状态 255。

Answer 2

fork 级别太低了。 IPC::Open3 是您应该使用的最低要求。

use IPC::Open3 qw( open3 );

open(local *CHILD_STDIN, '<', '/dev/null') or die $!;
open(local *CHILD_STDOUT, '>', $stdout) or die $!;

my $pid = open3(
   '<&CHILD_STDIN',
   '>&CHILD_STDOUT',
   \local *CHILD_STDERR,
   $prog, @$args
);

open(my $stderr_fh, '>', $stderr) or die $!;
while (<CHILD_STDERR>) {
   print $stderr_fh $ts . $_;
}

waitpid($pid, 0);