如何在不知道 perl 中的目录名称的情况下读取目录和子目录？

Question

您好，我想在不知道目录名称的情况下读取目录和子目录。当前目录是“D:/Temp”。 'Temp' 具有像 'A1'、'A2' 这样的子目录。同样，“A1”具有像“B1”、“B2”这样的子目录。同样，“B1”具有像“C1”、“C2”这样的子目录。 Perl 脚本不知道这些目录。因此，它必须首先找到目录，然后在目录“C1”中一次读取一个文件，一旦在“C1”中读取所有文件，它应该更改为“C2”目录。我在这里尝试了以下代码，我不想读取数组（@files）中的所有文件，但一次需要一个文件。数组中的 @dir 元素应为 fallows。

$dir[0] = "D:/Temp/A1/B1/C1"
$dir[1] = "D:/Temp/A1/B1/C2"
$dir[2] = "D:/Temp/A1/B2/C1"

下面是我试过的代码。

    use strict;
    use File::Find::Rule;
    use Data::Dumper;

    my $dir = "D:/Temp";
    my @dir = File::Find::Rule->directory->in($dir);
    print Dumper (\@dir);
    my $readDir = $dir[3];
    opendir ( DIR, $readDir ) || die "Error in opening dir $readDir\n";
    my @files = grep { !/^\.\.?$/ } readdir DIR;
    print STDERR "files: @files \n\n";

    for my $fil (@files) {
        open (F, "<$fil");
        read (F, my $data);
        close (F);
        print "$data";
    }

Answer 1

use File::Find;

use strict;
use warnings;

my @dirs;
my %has_children;

find(sub {
    if (-d) {
        push @dirs, $File::Find::name;
        $has_children{$File::Find::dir} = 1;
    }
}, 'D:/Temp');

my @ends = grep {! $has_children{$_}} @dirs;

print "$_\n" for (@ends);

Answer 2

您的目标：找到那些本身没有子目录的目录的绝对路径。

我将把这些感兴趣的目录称为终端目录。这是一个功能的原型，我相信它可以提供您正在寻找的便利。该函数将其结果作为列表返回。

my @list = find_terminal_directories($full_or_partial_path);

这是find_terminal_directories() 的一个实现。请注意，此实现不需要使用任何全局变量。另请注意使用称为递归的私有帮助函数。

在我的 Windows 7 系统上，对于输入目录 C:/Perl/lib/Test，我得到了输出：

== List of Terminal Folders ==
c:/Perl/lib/Test/Builder/IO
c:/Perl/lib/Test/Builder/Tester
c:/Perl/lib/Test/Perl/Critic

== List of Files in each Terminal Folder: ==
c:/Perl/lib/Test/Builder/IO/Scalar.pm
c:/Perl/lib/Test/Builder/Tester/Color.pm
c:/Perl/lib/Test/Perl/Critic/Policy.pm

实施

#!/usr/bin/env perl

use strict;
use warnings;
use Cwd qw(abs_path getcwd);

my @dir_list = find_terminal_directories("C:/Perl/lib/Test");
print "== List of Terminal Directories ==\n";
print join("\n", @dir_list), "\n";

print "\n== List of Files in each Terminal Directory: ==\n";
for my $dir (@dir_list) {
    for my $file (<"$dir/*">) {
        print "$file\n";
        open my $fh, '<', $file or die $!;
        my $data = <$fh>;  # slurp entire file contents into $data
        close $fh;

        # Now, do something with $data !
    }
}

sub find_terminal_directories {
    my $rootdir = shift;

    my @wanted;
    my $cwd = getcwd();
    chdir $rootdir;
    find_terminal_directories_helper(".", \@wanted);
    chdir $cwd;
    return @wanted;
}

sub find_terminal_directories_helper {
    my ($dir, $wanted) = @_;
    return if ! -d $dir;
    opendir(my $dh, $dir) or die "open directory error!";
    my $count = 0;
    foreach my $child (readdir($dh)) {
        my $abs_child = abs_path($child);
        next if (! -d $child || $child eq "." || $child eq "..");
        ++$count;
        chdir $child;
        find_terminal_directories_helper($abs_child, $wanted);  # recursion!
        chdir "..";
    }
    push @$wanted, abs_path($dir) if ! $count;  # no sub-directories found!
}

Answer 3

也许以下内容会有所帮助：

use strict;
use warnings;
use File::Find::Rule;

my $dir = "D:/Temp";
local $/;

my @dirs =
  sort File::Find::Rule->exec( sub { File::Find::Rule->directory->in($_) == 1 }
  )->directory->in($dir);

for my $dir (@dirs) {
    for my $file (<"$dir/*">) {
        open my $fh, '<', $file or die $!;
        my $data = <$fh>;
        close $fh;
        print $data;
    }
}

• local $/; 让我们slurp 将文件的内容放入一个变量中。如果您只想阅读第一行，请将其删除。
• exec() 中的sub 仅用于传递不包含目录的目录
• sort 用于按照您想要的顺序排列这些目录
• 一个文件glob<"$dir/*">用于获取每个目录下的文件

编辑：已修改代码以仅查找“终端目录”。感谢 DavidRR 对此规范的说明。

Answer 4

我会使用File::Find

示例脚本：

#!/usr/bin/perl

use strict; 
use warnings;

use File::Find;

my $dir = "/home/chris";

find(\&wanted, $dir);

sub wanted {
    print "dir: $File::Find::dir\n";
    print "file in dir: $_\n";
    print "complete path to file: $File::Find::name\n";
}

输出：

$ test.pl
dir: /home/chris/test_dir
file in dir: test_dir2
complete path to file: /home/chris/test_dir/test_dir2
dir: /home/chris/test_dir/test_dir2
file in dir: foo.txt
complete path to file: /home/chris/test_dir/test_dir2/foo.txt
...

Answer 5

使用反引号，将子目录和文件写入一个名为 filelist 的文件：

`ls -R $dir > filelist`