如何使用 Perl 从 HTML 中删除外部链接？

Question

我正在尝试从 HTML 文档中删除外部链接，但保留锚点，但我运气不佳。以下正则表达式

$html =~ s/<a href=".+?\.htm">(.+?)<\/a>/$1/sig;

将匹配锚标记的开头和外部链接标记的结尾，例如

<a HREF="#FN1" name="01">1</a>
some other html
<a href="155.htm">No. 155
</a> <!-- end tag not necessarily on the same line -->

所以我最终什么都没有，而不是

<a HREF="#FN1" name="01">1</a>
some other html

碰巧所有锚的 href 属性都是大写的，所以我知道我可以进行区分大小写的匹配，但我不想依赖它在未来总是如此。

我可以改变什么，让它只匹配a标签吗？

Answer 1

呼应 Chris Lutz 的评论，我希望以下内容表明使用解析器非常简单（特别是如果您希望能够处理您尚未见过的输入，例如 <a class="external" href="...">），而不是放在一起使用s/// 的脆弱解决方案。

如果您打算采用s/// 路线，至少老实说，一定要依赖href 属性全部大写，而不是假装灵活。

编辑：应大众需求 ;-)，这里是使用 HTML::TokeParser::Simple 的版本。仅使用 HTML::TokeParser 查看版本的编辑历史记录。

#!/usr/bin/perl

use strict; use warnings;
use HTML::TokeParser::Simple;

my $parser = HTML::TokeParser::Simple->new(\*DATA);

while ( my $token = $parser->get_token ) {
    if ($token->is_start_tag('a')) {
        my $href = $token->get_attr('href');
        if (defined $href and $href !~ /^#/) {
            print $parser->get_trimmed_text('/a');
            $parser->get_token; # discard </a>
            next;
        }
    }
    print $token->as_is;
}

__DATA__
<a HREF="#FN1" name="01">1</a>
some other html
<a href="155.htm">No. 155
</a> <!-- end tag not necessarily on the same line -->
<a class="external" href="http://example.com">An example you
might not have considered</a>

<p>Maybe you did not consider <a
href="test.html">click here >>></a>
either</p>

输出：

C:\Temp> hjk
<a HREF="#FN1" name="01">1</a>
some other html
No. 155 <!-- end tag not necessarily on the same line -->
An example you might not have considered

<p>Maybe you did not consider click here >>>
either</p>

注意：如果链接到的文件具有.html 扩展名而不是.htm，则您检查为“正确”的基于正则表达式的解决方案会中断。鉴于此，我发现您担心不依赖大写 HREF 属性是没有根据的。 如果你真的想要又快又脏，你不应该为其他任何事情而烦恼，你应该应该依靠全部大写的HREF 并完成它。但是，如果您想确保您的代码能够处理更多种类的文档并使用更长时间，那么您应该使用适当的解析器。

Answer 2

HTML::Parser 有点像 SAX 类型解析器：

use strict;
use warnings;

use English qw<$OS_ERROR>;
use HTML::Parser;
use List::Util qw<first>;

my $omitted;

sub tag_handler { 
    my ( $self, $tag_name, $text, $attr_hashref ) = @_;
    if ( $tag_name eq 'a' ) { 
        my $href = first {; defined } @$attr_hashref{ qw<href HREF> };
        $omitted = substr( $href, 0, 7 ) eq 'http://';
        return if $omitted;
    }
    print $text;
}

sub end_handler { 
    my $tag_name = shift;
    if ( $tag_name eq 'a' && $omitted ) { 
        $omitted = false;
        return;
    }
    print shift;
}

my $parser
    = HTML::Parser->new( api_version => 3
                       , default_h   => [ sub { print shift; }, 'text' ]
                       , start_h     => [ \&tag_handler, 'self,tagname,text,attr' ]
                       , end_h       => [ \&end_handler, 'tagname,text' ]
                       );
$parser->parse_file( $path_to_file ) or die $OS_ERROR;

Answer 3

另一种解决方案。我爱HTML::TreeBuilder 和家人。

#!/usr/bin/perl
use strict;
use warnings;
use HTML::TreeBuilder;

my $root = HTML::TreeBuilder->new_from_file(\*DATA);
foreach my $a ($root->find_by_tag_name('a')) {
    if ($a->attr('href') !~ /^#/) {
        $a->replace_with_content($a->as_text);
    }
}
print $root->as_HTML(undef, "\t");

__DATA__
<a HREF="#FN1" name="01">1</a>
some other html
<a href="155.htm">No. 155
</a> <!-- end tag not necessarily on the same line -->
<a class="external" href="http://example.com">An example you
might not have considered</a>

<p>Maybe you did not consider <a
href="test.html">click here >>></a>
either</p>

Answer 4

为什么不只删除 href 属性不以井号开头的链接呢？像这样的：

html =~ s/<a href="[^#][^"]*?">(.+?)<\/a>/$1/sig;

Answer 5

更简单，如果你不关心标签属性：

$html =~ s/<a[^>]+>(.+?)<\/a>/$1/sig;