atom feed：将多个 <author> 项目合并为一个的脚本？ [关闭]

Question

我想编写一个命令行脚本，它将来自 atom 提要的多个 <author> 标签合并为一个。例如，这样的条目：

<entry>
    <id>someid</id>
    <published>somedate</published>
    <title>Title</title>
    <summary>Summary</summary>
    <author>
      <name>Author One</name>
    </author>
    <author>
      <name>Author Two</name>
    </author>
    <author>
      <name>Author Three</name>
    </author>
  </entry>

应该变成：

<entry>
    <id>someid</id>
    <published>somedate</published>
    <title>Title</title>
    <summary>Summary</summary>
    <author>
      <name>Author One, Author Two, Author Three</name>
    </author>
  </entry>

我想我可以自己使用 Perl 和正则表达式来完成，但是，由于使用正则表达式解析 XML 不是一个好主意，我会感谢使用适当的 xml 解析器的更优雅的解决方案。

Answer 1

Ted 的想法是正确的，但有些事情以比需要的更复杂的方式完成，而且他们不知道 Atom 格式的属性（例如，它使用 namespaces）。

use XML::LibXML               qw( );
use XML::LibXML::XPathContext qw( );

my $xpc = XML::LibXML::XPathContext->new();
$xpc->registerNs(a => 'http://www.w3.org/2005/Atom');

# See XML::LibXML::Parser for more ways to create the document object.
my $doc = XML::LibXML->load_xml( location => 'atom.xml' );

for my $entry_node ($xpc->findnodes('/a:feed/a:entry', $doc)) {
   my @author_names;
   for my $author_node ($xpc->findnodes('a:author', $entry_node)) {
      push @author_names, $xpc->findvalue('a:name', $author_node);
      $author_node->unbindNode();
   }

   my $author_node = XML::LibXML::Element->new('author');
   my $name = $author_node->appendTextChild('name', join(", ", @author_names));
   $entry_node->appendChild($author_node);
}

$doc->toFile('atom.new.xml');

Answer 2

在 Perl 中，我建议使用 XML::LibXML。

在这里，我使用Xpath 查询来查找name 节点，然后将所有名称推送到一个数组中，同时删除author 节点。最后，我创建了一个新的 author 节点并被追加。

#!/usr/bin/perl

use strict;
use warnings;

use XML::LibXML;

# example loading the xml from a file
my $dom = XML::LibXML->load_xml(location => 'atom.xml', no_blanks => 1);
my $root = $dom->documentElement();

# the Xpath query
my $query = q{
    /entry/author/name
};

my @authornames;

foreach my $namenode ($dom->findnodes($query)) {
    # save the name
    push @authornames, $namenode->to_literal();

    # remove the author node
    $namenode->getParentNode->getParentNode->removeChild($namenode->getParentNode);

    #or:
    # $root->removeChild($namenode->getParentNode);
}

# build a new author node
my $author = XML::LibXML::Element->new('author');
$author->appendTextChild('name', join(", ",@authornames));

# and add it
$root->appendChild($author);

# print the result
print $dom->serialize(1);

#or, if you don't want the <?xml...> header:
# print $root->serialize(1) . "\n";

输出：

<?xml version="1.0"?>
<entry>
  <id>someid</id>
  <published>somedate</published>
  <title>Title</title>
  <summary>Summary</summary>
  <author>
    <name>Author One, Author Two, Author Three</name>
  </author>
</entry>