【问题标题】:How to convert tag names and values from XML into HTML using Perl如何使用 Perl 将标签名称和值从 XML 转换为 HTML
【发布时间】:2015-09-19 06:02:11
【问题描述】:

有没有什么方法可以使用 Perl 将一个简单的 XML 文档转换为 HTML,这会给我一个标签名称和标签值的表格?

XML文件output.xml是这样的

<?xml version="1.0"?>

<doc>
    <GI-eSTB-MIB-NPH>
        <eSTBGeneralErrorCode.0>INTEGER: 0</eSTBGeneralErrorCode.0>
        <eSTBGeneralConnectedState.0>INTEGER: true(1)</eSTBGeneralConnectedState.0>
        <eSTBGeneralPlatformID.0>INTEGER: 2076</eSTBGeneralPlatformID.0>
        <eSTBGeneralFamilyID.0>INTEGER: 25</eSTBGeneralFamilyID.0>
        <eSTBGeneralModelID.0>INTEGER: 60436</eSTBGeneralModelID.0>
        <eSTBMoCAMACAddress.0>STRING: 0:0:0:0:0:0</eSTBMoCAMACAddress.0>
        <eSTBMoCANumberOfNodes.0>INTEGER: 0</eSTBMoCANumberOfNodes.0>
    </GI-eSTB-MIB-NPH>
</doc>

我正在尝试创建如下所示的 HTML

1. eSTBGeneralPlatformID.0 - INTEGER: 2076
2. eSTBGeneralFamilyID.0 - INTEGER: 25
3. 

我试图使用来自网络的代码,但我真的很难理解如何为 HTML 标签生成所需的格式。

我正在尝试的是这个

#!/usr/bin/perl

use strict;
use warnings;

use XML::Parser;
use XML::LibXML;

#Add TagNumberConversion.pl here

my $parser = XML::Parser->new();
$parser->setHandlers(
    Start => \&start,
    End   => \&end,
    Char  => \&char,
    Proc  => \&proc,
);

my $header = &getXHTMLHeader();
print $header;

$parser->parsefile( '20150630104826.xml' );

my $currentTag = "";

sub start() {

    my ( $parser, $name, %attr ) = @_;
    $currentTag = $name;

    if ( $currentTag eq 'doc' ) {
        print "<head><title>"
            . "Output of snmpwalk for cpeIP4"
            . "</title></head>";
        print "<body><h2>" . "Output of snmpwalk for cpeIP4" . "</h2>";
        print '<table summary="'
            . "Output of snmpwalk for cpeIP4"
            . '"><tr><th>Tag Name</th><th>Tag Value</th></tr>';
    }
    elsif ( $currentTag eq 'GI-eSTB-MIB-NPH' ) {
        print "<tr>";
    }
    elsif ( $currentTag =~ /^eSTB/ ) {
        print "<tr>";
    }
    else {
        print "<td>";
    }
}

sub end() {

    my ( $parser, $name, %attr ) = @_;
    $currentTag = $name;

    if ( $currentTag eq 'doc' ) {
        print "</table></body></html>";
    }
    elsif ( $currentTag eq 'GI-eSTB-MIB-NPH' ) {
        print "</tr>";
    }
    elsif ( $currentTag =~ /^eSTB/ ) {
        print "</tr>";
    }
    else {
        print "</td>";
    }
}

sub char() {
    my ( $parser, $data ) = @_;

    print $data;
}

sub proc() {
    my ( $parser, $target, $data ) = @_;

    if ( lc( $target ) eq 'perl' ) {
        $data = eval( $data );
        print $data;
    }
}

sub getXHTMLHeader() {

    my $header = '<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE html
PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN"
"http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">';

    return $header;
}

这是正在编写的代码,但我意识到这对我的要求来说太过分了。

所以我想弄清楚是否有任何使用 Perl 的快速方法。

如果确实有任何快速的方法,请给我一些指示。

【问题讨论】:

  • 在调用 Perl 子例程时不应该使用 & 符号 &amp; —— 只有 my $header = getXHTMLHeader() 是正确的。并且在定义子例程时不应该使用原型——那些在子例程名称之后的() 确保不会传递任何参数,这根本不是您想要的。只是sub start { ... } 是正确的。并且你应该为包名等全局标识符保留大写字母——本地标识符应该由小写字母、十进制数字和下划线组成
  • 如果您显示您想要作为输出的实际 HTML 将会有很大帮助

标签: html xml perl


【解决方案1】:

快速而肮脏的方法是只使用正则表达式。然而,它伴随着丢失一些数据并被边缘情况烧毁的风险。但是既然你要求...

#!/usr/bin/env perl

use strict;

open my $fh, 'filename.xml'
    or die "unable to open filename.xml : $!";
my $count = 1;
print "<head><title>'Output of snmpwalk for cpeIP4'</title></head>\n";
print "<body><h2>'Output of snmpwalk for cpeIP4'</h2>\n";
print "<table summary='Output of snmpwalk for cpeIP4'><tr><th>Tag Name</th><th>Tag Value</th></tr>\n";
while (my $line = <$fh>) {
    next unless $line =~ m|<eSTB|;
    # Store into into $tag and $value
    # the result of matching whitespace, followed by '<'
    # followed by anything (store into $tag)
    # followed by '>'
    # followed by anything (store into $value)
    # followed by '<'
    my ($tag, $value) = $line =~ m|\s+<(.+?)>(.+?)<|;
    print "<tr><td>" . $count++ . ". $tag</td><td>$value</td></tr>\n";
}
print "</table></body></html>\n";

产生以下内容:

<head><title>'Output of snmpwalk for cpeIP4'</title></head>
<body><h2>'Output of snmpwalk for cpeIP4'</h2>
<table summary='Output of snmpwalk for cpeIP4'><tr><th>Tag Name</th><th>Tag Value</th></tr>
<tr><td>1. eSTBGeneralErrorCode.0</td><td>INTEGER: 0</td></tr>
<tr><td>2. eSTBGeneralConnectedState.0</td><td>INTEGER: true(1)</td></tr>
<tr><td>3. eSTBGeneralPlatformID.0</td><td>INTEGER: 2076</td></tr>
<tr><td>4. eSTBGeneralFamilyID.0</td><td>INTEGER: 25</td></tr>
<tr><td>5. eSTBGeneralModelID.0</td><td>INTEGER: 60436</td></tr>
<tr><td>6. eSTBMoCAMACAddress.0</td><td>STRING: 0:0:0:0:0:0</td></tr>
<tr><td>7. eSTBMoCANumberOfNodes.0</td><td>INTEGER: 0</td></tr>
</table></body></html>

【讨论】:

  • 非常感谢 xxfelixxx。我用了你快速而肮脏的方式,它完美地完成了工作。我试图理解以下行,我认为它正在做模式匹配等等,比如将 $line 的特定部分放入 $tag 和 $value 字符串中: my ($tag, $value) = $line =~ m|\s+(.+)
  • 1.存储到变量 $tag 和 $value 2. $line 模式匹配的结果 3. 匹配空格后跟一个 ' ' 后跟任何东西 6. 捕获它进入 $value 的“任何东西” 7. 然后是 '
  • 嗯...用正则表达式解析 XML。那 never 出错 :-/
  • Dave,我尝试安装 Template 模块,这样我就可以使用 LibXML 而不是使用正则表达式,但发现我正在使用的 Linux 机器上没有安装 CPAN(或者至少现在不工作)。但我会让 CPAN 正常工作,并将使用 LibXML 进行解析,因为这对我来说是一种更可靠的方法和很好的学习方法。
  • 没有 Tempalte Toolkit 不会阻止您使用 XML::LibXML 来解析 XML。您只需要使用不同的方法来创建输出。
【解决方案2】:

首先,我认为您为此使用了错误的工具。我总是发现XML::LibXML 比 XML::Parser 更容易使用。您加载 XML::LibXML,但您从未使用过它。

其次,如果您将其视为两个阶段,我认为您会发现您的生活会更轻松 - 一个用于提取数据,一个用于输出新数据。

这是第一阶段,它将您需要的数据存储在一个数组中。

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

use XML::LibXML;
use Data::Dumper;

my $file = shift || die "Must give XML file\n";

my $parser = XML::LibXML->new();
my $doc = $parser->parse_file($file);

my @tags;

# Find the nodes using an XPath expression
foreach ($doc->findnodes('//GI-eSTB-MIB-NPH/*')) {
  push @tags, { name => $_->nodeName, content => $_->textContent };
}

# Just here to show the intermediate data structure
say Dumper \@tags;

然后您需要使用@tags 来生成您的输出。十五年来,我们都知道在 Perl 代码中包含硬编码 HTML 是一个糟糕的主意,因此我强烈建议您使用像 Template Toolkit 这样的模板系统。

我创建了一个像这样的xml.tt 文件:

<html>
<head>
<title>Output of snmpwalk for cpeIP4</title>
</head>
<body><h2>Output of snmpwalk for cpeIP4</h2>
<table summary='Output of snmpwalk for cpeIP4'>
<tr>
<th>Tag Name</th><th>Tag Value</th><
/tr>
[% FOREACH tag IN tags -%]
<tr><td>[% loop.count %]. [% tag.name %]</td><td>[% tag.content %]</td></tr>
[% END -%]
</table>
</body>
</html>

然后我的程序的后半部分是这样的:

use Template;

my $tt = Template->new;
$tt->process('xml.tt', { tags => \@tags });

我希望你同意所有看起来都比你的方法简单得多。

【讨论】:

  • 谢谢戴夫。我同意您提供的解决方案比我尝试的解决方案过于简洁和简单。我想我没有“模板”的支持模块。我收到错误消息:无法在 @INC 中找到 Template.pm(@INC 包含:/usr/local/lib64/perl5 /usr/local/share/perl5 /usr/lib64/perl5/vendor_perl /usr/share/ perl5/vendor_perl /usr/lib64/perl5 /usr/share/perl5 .) 在 Call_to_snmpwalk_V_8.pl 第 14 行。BEGIN 失败——编译在 Call_to_snmpwalk_V_8.pl 第 14 行中止。我正在尝试找出如何纠正此错误。我已经包含了 use 5.010 并且我在 perl v5.10.1
  • 听起来你没有安装模板模块。你只需要通过任何你用来安装 CPAN 模块的方式来安装它。
猜你喜欢
  • 2019-10-02
  • 1970-01-01
  • 2017-08-16
  • 2023-03-23
  • 2012-12-05
  • 2017-12-25
  • 2014-12-21
  • 2010-11-10
  • 2017-04-02
相关资源
最近更新 更多