检查文本行中的字段是否与值匹配

Question

我一直在使用以下 Perl 代码从多个文本文件中提取文本。它工作正常。

其中一个输入文件中的几行示例：

Fa0/19    CUTExyz     notconnect   129         half    100 10/100BaseTX
Fa0/22    xyz MLS     notconnect   1293        half     10 10/100BaseTX

我需要的是精确匹配每一行中的数字（即129 与1293 不匹配）并打印相应的行。

匹配一系列数字也会很好，将特定数字排除在外，即匹配 2 到 10，但不匹配 11 到 12 到 20

#!/perl/bin/perl

use warnings;

my @files = <c:/perl64/files/*>;

foreach $file ( @files ) {

    open( FILE, "$file" );

    while ( $line = <FILE> ) {
        print "$file $line" if $line =~ /123/n;
    }

    close FILE;
}

谢谢你的建议，但是可以使用上面的代码结构吗？

Answer 1

我建议你看看perldoc perlre。

您需要锚定您的正则表达式模式。最简单的方法可能是使用\b，它是字母数字和非字母数字之间的零宽度边界。

#!/perl/bin/perl
use warnings;
use strict;

foreach my $file ( glob "c:/perl64/files/*" ) {
   open( my $input, '<', $file ) or die $!;
   while (<$input>) {
      print "$file $_" if m/\b123\b/;
   }
   close $input;
}

注意 - 你应该使用三参数 open 和上面的词法文件句柄，因为这是更好的做法。

我还删除了 n 模式修饰符，因为它看起来是多余的。

在您进行编辑后，给我们一些源数据。我建议解决方案是 not 使用正则表达式 - 您的源数据看起来是空格分隔的。 （也许那些是标签？）。

所以我建议您最好使用split 并选择您想要的字段，并对其进行数字测试，因为您提到了匹配范围。这不适合正则表达式，因为它们不理解数字内容。

改为：

while ( <$input> ) {
   print if (split)[-4] == 129;
}

注意 - 我在 split 中使用 -4，它从列表的 end 开始索引。 这是因为第 3 列包含空格，所以除非我们从数组末尾倒数，否则在空格上拆分会产生错误的结果。使用负索引，我们每次都得到正确的字段。

如果您的数据是制表符分隔的，那么您可以使用chomp 和split /\t/。或者可能在/\s{2,}/ 上拆分以拆分为 2 个或多个空格

但是通过选择字段，您可以对其进行数字测试，例如

if $fields[-4] > 100 and $fields[-4] < 200

等等

Answer 2

我希望你没有得到你想要的答案，因为你不熟悉 Perl，所以放弃了最佳实践。问如何编写一个丑陋的解决方案是不合适的，因为正确的 Perl 超出你的能力范围

正如本网站反复所说的那样，如果您不知道如何做一份工作，那么您应该雇用知道的人并为他们的工作付费。我所知道的其他职业都没有期望免费完成高质量的工作

这里有一些关于您的代码的注释。无论您在哪里学习技术，您一直在寻找一个非常过时的资源

• 你真的有一个根目录perl，所以你的编译器是/perl/bin/perl吗？这很不寻常，在 Windows 中没有必要使用 shebang 行

• 您必须始终在您编写的每个 Perl 程序的顶部添加use strict 和use warnings 'all'，并使用@987654326 声明所有变量@尽可能接近他们的第一个使用点。出于某种原因，您使用@files 执行此操作，但不是使用$file

• 最好将<c:/perl64/files/*> 替换为glob 'C:/perl64/files/*'。否则代码不太清楚，因为 Perl 重载了 <> 运算符

• 不要将变量名放在双引号内。充其量是不必要的，并且可能会导致错误。所以"$file" 应该是$file

• 始终使用open的三参数版本，这样第二个参数就是开启模式

• 不要使用全局文件句柄。并且总是测试文件是否已正确打开，如果open 失败，则会显示包含$! 的消息——失败的原因

  open( FILE, "$file" )
  

  应该是这样的

  open my $fh, '<', $file or die qq{Unable to open "$file" for input: $!}
  

• 不要对所有事情都依赖正则表达式模式。在这种情况下，split 似乎是更好的选择，或者如果您的记录具有固定宽度的字段，则可能是 unpack。在下面的解决方案中，我在“多个空格”上使用了split，但是如果您的真实数据与您显示的不同（制表符分隔？）那么这将不起作用

  请注意，Fa0/129 也将与您当前的方法匹配

此 Perl 程序过滤您的数据，打印第四个字段 $lines[3]（由多个空格字符划定）在数值上等于 129 的行

当输入为单个文件 splitn.txt 时，会产生显示的输出，其中包含您问题中显示的数据

use strict;
use warnings 'all';

for my $file ( glob 'C:/perl64/files/*' ) {

    open my $fh, '<', $file or die qq{Unable to open "$file" for input: $!};

    while ( my $line = <$fh> ) {
        chomp;
        my @fields = split /\s\s+/, $line;
        print "$file $line" if $fields[3] == 129;
    }
}

输出

splitn.txt Fa0/19    CUTExyz     notconnect   129         half    100 10/100BaseTX

Answer 3

您的问题不清楚。当你说：

我需要的是准确匹配每一行中的数字

这可能意味着几件事。这可能意味着每一行只包含一个您想要匹配的数字。在这种情况下，使用== 可能比使用正则表达式更好。或者这可能意味着您在一行上有很多文本，而您只想匹配完整的数字。在这种情况下，您应该使用\b（“单词边界”锚点）-/\b123\b/。

如果您的问题更清楚（也许通过向我们提供示例输入），那么人们将不必猜测您的意思。

您的代码还有几点：

• 始终包括use strict 和use warnings。
• 始终检查来自open() 的返回值，并对失败采取适当的措施。
• 使用词法文件句柄和 open() 的 3-arg 版本。
• 无需在您的open() 通话中引用$file。
• 使用$_ 可以简化您的代码。
• 除非您的正则表达式包含括号，否则匹配运算符上的 /n 无效。

将所有这些放在一起（并假设我对您问题的第二种解释是正确的），您的代码可能如下所示：

#!/perl/bin/perl

use strict;
use warnings;

my @files = <c:/perl64/files/*>;

foreach my $file (@files) {
  open my $file_h, '<', $file
    or die "Can't open $file: $!";

  while (<$file_h>) {
    print "$file $_\n" if /\b123\b/;
  }

  # No need to close $file_h as it is closed
  # automatically when the variable goes out
  # of scope.
}