如何在具有不同序列化程序的 Dancer2 应用程序之间共享会话数据？

Question

我正在尝试将应用程序从 Dancer 迁移到 Dancer2。我的想法是将代码分成由模板提供的路由和作为 Ajax (API) 调用的路由。

我的基础应用是：

use strict;
use warnings;
use FindBin; 
use Plack::Builder;

use Routes::Templates;
use Routes::Login; 

builder {
    mount '/'    => Routes::Templates->to_app;
    mount '/api' => Routes::Login->to_app;
};

我在想Routes::Templates 包没有任何序列化程序，而Routes::Login 包将有 JSON 序列化。我用过

set serializer => 'JSON';

在Routes::Login 包中。

但是，我也希望这些共享会话数据，以便每个都有一个共同的应用名称

use Dancer2 appname => 'myapp';

在每个文件中。这似乎在序列化方面遇到了麻烦。 Routes::Template 路由没有正确返回，因为它试图被编码为 JSON。这是错误：

无法序列化内容：需要 hash- 或 arrayref（不是简单的标量，使用 allow_nonref 允许这样做）

我已阅读所有文档，包括这些：

• How can I use Dancer2::Plugin::Database when my code is split into multiple files?
• https://github.com/wyoung/advent-calendar/tree/master/danceradvent/public/articles/2015

但我仍然不清楚序列化程序是如何按包分隔的。

Answer 1

无需使用appname 组合您的应用；只要两个应用程序使用相同的会话引擎配置，会话数据就会被共享。 （另外，serializers are an all-or-nothing prospect 在 Dancer2 中，所以你真的必须使用两个独立的应用程序。）

这是我在dancer-users mailing list 上给出的示例：

MyApp/lib/MyApp.pm

package MyApp;
use Dancer2;

our $VERSION = '0.1';

get '/' => sub {
    session foo => 'bar';
    template 'index';
};

true;

MyApp/lib/MyApp/API.pm

package MyApp::API;
use Dancer2;

set serializer => 'JSON';

get '/' => sub {
    my $foo = session('foo') // 'fail';
    return { foo => $foo };
};

true;

MyApp/bin/app.psgi

#!/usr/bin/env perl

use strict;
use warnings;
use FindBin;
use lib "$FindBin::Bin/../lib";

use MyApp;
use MyApp::API;
use Plack::Builder;

builder {
    mount '/'    => MyApp->to_app;
    mount '/api' => MyApp::API->to_app;
};

如果您在同一浏览器中访问/ 路由，然后访问/api 路由，您将获得

{"foo":"bar"}

表示两个请求都使用了相同的会话变量。