如何在 Perl 中合并哈希？

Question

我有一个哈希引用数组。哈希包含 2 个键，USER 和 PAGES。这里的目标是遍历哈希引用数组，并保持用户在打印机上打印的页面总数（这来自事件日志）。我从 Excel 电子表格中提取数据并使用正则表达式提取用户名和页面。电子表格中有 182 行，每行包含一个用户名和他们在该作业上打印的页数。目前该脚本可以使用用户名和他们打印的页面打印每个打印作业（全部 182 个），但我想将其合并，以便它显示：用户名 266（即只显示一次用户名，以及他们打印的总页数整个电子表格。

这是我尝试遍历哈希引用数组，查看用户是否已经存在，如果存在，+= 该用户的页数进入新的哈希引用数组（较小的）。如果没有，则将用户添加到新的哈希引用数组中：

my $criteria = "USER";
my @sorted_users = sort { $a->{$criteria} cmp $b->{$criteria} } @user_array_of_hash_refs;

my @hash_ref_arr;
my $hash_ref = \@hash_ref_arr;

foreach my $index (@sorted_users)
{
    my %hash = (USER=>"",PAGES=>"");
    if(exists $index{$index->{USER}})
    {
        $hash{PAGES}+=$index->{PAGES};
    }
    else
    {
        $hash{USER}=$index->{USER};
        $hash{PAGES}=$index->{PAGES};
    }
    push(@hash_ref_arr,{%hash});
}

但它给了我一个错误：

全局符号“%index”需要显式的包名...

也许我的逻辑不是最好的。我应该改用数组吗？考虑到我的数据的性质，似乎散列是最好的选择。我只是不知道如何将哈希引用数组缩小到只得到一个用户名和他们打印的总页数（我知道我看起来很多余，但我只是想清楚）。谢谢。

Answer 1

my %totals;

$totals{$_->{USER}} += $_->{PAGES} for @user_array_of_hash_refs;

然后，取出数据：

print "$_ : $totals{$_}\n" for keys %totals;

您也可以按使用情况排序：

print "$_ : $totals{$_}\n" for sort { $totals{$a} <=> $totals{$b} } keys %totals;

Answer 2

正如 mkb 提到的，错误在以下行：

if(exists $index{$index->{USER}})

但是，在阅读您的代码后，您的逻辑是错误的。简单地纠正语法错误不会提供您想要的结果。

我建议在循环中跳过使用临时哈希。只需直接使用结果哈希即可。

例如：

#!/usr/bin/perl
use strict;
use warnings;

my @test_data = (
    { USER => "tom", PAGES => "5" },
    { USER => "mary", PAGES => "2" },
    { USER => "jane", PAGES => "3" },
    { USER => "tom", PAGES => "3" }
);

my $criteria = "USER";
my @sorted_users = sort { $a->{$criteria} cmp $b->{$criteria} } @test_data;

my %totals;

for my $index (@sorted_users) {
    if (not exists $totals{$index->{USER}}) {
        # initialize total for this user
        $totals{$index->{USER}} = 0;
    }

    # add to user's running total
    $totals{$index->{USER}} += $index->{PAGES}
}

print "$_: $totals{$_}\n" for keys %totals;

这会产生以下输出：

$ ./test.pl
jane: 3
tom: 8
mary: 2

Answer 3

错误来自这一行：

if(exists $index{$index->{USER}})

Perl 5 中的$ 符号在名称后带有{} 表示您从哈希中获取标量值。名称 %index 没有声明散列。我认为您可能只需要添加一个-> 运算符，因此问题行变为：

if(exists $index->{$index->{USER}})

但没有数据让我不确定。

另外，使用 use strict 对你有好处，否则你会默默地实例化 %index 哈希并想知道为什么你的结果没有任何意义。

Answer 4

my %total;
for my $name_pages_pair (@sorted_users) {
  $total{$name_pages_pair->{USER}} += $name_pages_pair->{PAGES};
}

for my $username (sort keys %total) {
  printf "%20s %6u\n", $username, $total{$username};
}