在 Perl 中使用数据引用的正确方法

Question

我有一组数据要处理。

为了简化我的代码，最好通过指向原始数据的引用数组来访问我的一些数据子集。

比解释更好，我写下了这个例子（它还没有工作）。最后，我想更新原始数据而不必更新所有子集。

可以用 Perl 做这样的事情吗？

#!/usr/bin/env perl
use strict;
use warnings;

# A set of data
my $design = {
    box => {
        ne =>  {data => 'north-east'},
        nw =>  {data => 'north-west'},
        n  =>  {data => 'north'},
        s  =>  {data => 'south'},
        e  =>  {data => 'east'},
        w  =>  {data => 'west'},
        se  => {data => 'south-east'},
        sw  => {data => 'south-west'}
    }
};

# Select a design
my $selected = 'box';

# Build some arrays
my $d = $design->{$selected};

my @eastside  = (\$d->{e}, \$d->{ne}, \$d->{se});
my @westside  = (\$d->{w}, \$d->{nw}, \$d->{sw});
my @northside = (\$d->{n}, \$d->{ne}, \$d->{nw});

# Update one data
$d->{ne}->{data} .= " updated!";

# Display
print join '', "Composed of:\n", map("\t".$_->{data}."\n", @eastside);

脚本应该输出：

Composed of:
   east
   north-east updated!
   south-east

Answer 1

所有的错误是你在像这样的行中引用了已经是哈希引用的值

my @eastside  = (\$d->{e}, \$d->{ne}, \$d->{se})

您应该简单地省略反斜杠，一切都会正常。

（顺便说一句，你可能想知道引用\ 运算符是可分配的，所以你可以用

my @eastside  = \( $d->{e}, $d->{ne}, $d->{se} )

但这样就不再正确了！）

其他几点

• 在需要使用多个键提取散列元素列表的情况下，您应该使用 散列切片。在这种情况下，@eastside 只是 @{$d}{qw/ ne e se /}

• Perl 允许省略右大括号和大括号对之间的间接运算符->，因此$d->{ne}->{data} 可以写成$d->{ne}{data}

• 您正在打印 join 的结果，元素之间为空。只需列出要打印的项目，您就会得到相同的结果。您还可以将哈希元素插入双引号字符串，因此"\t".$_->{data}."\n" 与"\t$_->{data}\n" 相同

进行这些更改会导致此工作程序

use strict;
use warnings;

# A set of data
my $design = {
   box => {
      ne => {data => 'north-east'},
      nw => {data => 'north-west'},
      n  => {data => 'north'},
      s  => {data => 'south'},
      e  => {data => 'east'},
      w  => {data => 'west'},
      se => {data => 'south-east'},
      sw => {data => 'south-west'},
   }
};

# Select a design
my $selected = 'box';

# Build some arrays
my $d = $design->{$selected};

my @eastside  = @{$d}{qw/ ne e se /};
my @westside  = @{$d}{qw/ nw w sw /};
my @northside = @{$d}{qw/ nw n ne /};

# Update one item
$d->{ne}{data} .= " updated!";

# Display
print "Composed of:\n"; 
print "   $_->{data}\n" for @eastside;

输出

Composed of:
   north-east updated!
   east
   south-east

Answer 2

您在@eastside 数组中有标量引用，因此为了取消引用标量，请在$_->{data} 前面添加额外的$，或使用${$_}->{data}。

print join '', "Composed of:\n", map("\t".$$_->{data}."\n", @eastside);

输出

Composed of:
    east
    north-east updated!
    south-east

Answer 3

您可以使用 Data::Dumper 模块检查数据结构。

还要检查接下来的两个@east2 和@east3 示例，尤其是@east3 是如何构建的。

#!/usr/bin/env perl
use 5.010;
use warnings;
use Data::Dumper;

# A set of data
my $design = {
    box => {
        ne =>  {data => 'north-east'}, nw =>  {data => 'north-west'},
        n  =>  {data => 'north'}, s  =>  {data => 'south'},
        e  =>  {data => 'east'}, w  =>  {data => 'west'},
        se  => {data => 'south-east'}, sw  => {data => 'south-west'}
    }
};
my $selected = 'box';

my $d = $design->{$selected};

#your example
my @east1  = (\$d->{e}, \$d->{ne}, \$d->{se});
say Dumper \@east1;

my @east2  = ($d->{e}, $d->{ne}, $d->{se});
say Dumper \@east2;

my @east3 = @$d{qw(e ne se)};
say Dumper \@east3;

$d->{ne}->{data} .= " updated!";

print join '', "Composed of:\n", map("\t".$$_->{data}."\n", @east1);

print join '', "Composed of:\n", map("\t".$_->{data}."\n", @east2);
print join '', "Composed of:\n", map("\t".$_->{data}."\n", @east3);

打印：

$VAR1 = [
          \{
              'data' => 'east'
            },
          \{
              'data' => 'north-east'
            },
          \{
              'data' => 'south-east'
            }
        ];

$VAR1 = [
          {
            'data' => 'east'
          },
          {
            'data' => 'north-east'
          },
          {
            'data' => 'south-east'
          }
        ];

$VAR1 = [
          {
            'data' => 'east'
          },
          {
            'data' => 'north-east'
          },
          {
            'data' => 'south-east'
          }
        ];

Composed of:
    east
    north-east updated!
    south-east
Composed of:
    east
    north-east updated!
    south-east
Composed of:
    east
    north-east updated!
    south-east