可能重复：
How to replace a Perl hash key?
Changing keys in a “for ( keys %hash ) {}”-loop
我有一个像下面这样的哈希
test0 => '1'
test1 => '2'
我想把它变成
something0 => '1'
something1 => '2'
基本上，我想从哈希中取出每个键，用“某物”替换“测试”，然后将其放回原始哈希中。
【问题讨论】：
exact是什么意思？？？）
标签： perl
这适用于任何 1:1 映射，即使某些键是相同的。这会将 a 切换为 b（反之亦然）：
my @new_keys = keys %hash;
y/ab/ba/ foreach @new_keys;
@hash{@new_keys} = delete @hash{keys %hash};
诀窍是最后一行，它使用哈希切片同时替换所有键，因此冲突无关紧要。
这里是@ikegami 发布的方法的基准（修正了拼写错误）以及我上面的方法：
Rate ikegami_map ikegami_5.14 ikegami_for derobert
ikegami_map 38186/s -- -16% -19% -34%
ikegami_5.14 45547/s 19% -- -3% -22%
ikegami_for 47065/s 23% 3% -- -19%
derobert 58213/s 52% 28% 24% --
基准代码：
use List::MoreUtils qw(zip);
use Benchmark qw(cmpthese);
use v5.14;
use warnings qw(all);
our %hash = zip @{[ 'a'..'z' ]}, @{[ 1..26 ]};
%hash = map { y/a-z/n-za-m/r => $hash{$_} } keys(%hash);
cmpthese(-2, {
'derobert' => q{
my @new_keys = keys %hash;
y/a-z/n-za-m/ foreach @new_keys;
@hash{@new_keys} = delete @hash{keys %hash};
},
'ikegami_for' => q{
my %new_hash;
for my $orig (keys(%hash)) {
(my $new = $orig) =~ y/a-z/n-za-m/;
$new_hash{$new} = $hash{$orig};
}
%hash = %new_hash;
},
'ikegami_map' => q{
%hash = map {
(my $new = $_) =~ y/a-z/n-za-m/;
$new => $hash{$_}
} keys(%hash);
},
'ikegami_5.14' => q{
%hash = map { y/a-z/n-za-m/r => $hash{$_} } keys(%hash);
},
});
【讨论】：
my @new_keys = my @old_keys = grep tr/ab//, keys %hash; tr/ab/ba/ foreach @new_keys; @hash{@new_keys} = delete @hash{@old_keys};
%hash 词法，相反，它们都看到了%main::hash 全局，它是空的。这可以通过在每个测试中将q{ 更改为sub{ 来解决。此外，您不应该在基准测试中修改源数据集，否则可能会影响其他测试的结果。每个人都应该首先创建一个哈希副本。
使用for（假设每个新密钥都不同于每个现有密钥）：
for my $orig (keys(%hash)) {
(my $new = $orig) =~ s/^test/something/;
$hash{$new} = delete($hash{$orig});
}
使用for（任何替换都可以安全使用）：
my %new_hash;
for my $orig (keys(%hash)) {
(my $new = $orig) =~ s/^test/something/;
$new_hash{$new} = $hash{$orig};
}
%hash = %new_hash;
使用map（任何替换都可以安全使用）：
%hash = map {
(my $new = $_) =~ s/^test/something/;
$new => $hash{$_}
} keys(%hash);
使用 map 和 5.14+（可安全使用任何替换）：
%hash = map { s/^test/something/r => $hash{$_} } keys(%hash);
【讨论】：
map 方法因错字而无法使用，我将为您修正。实际上，它们都有相同的错字。实际上，我正在尝试对它们进行基准测试，请在发布之前测试您的代码。错字填充的代码让初学者感到困惑！
my @keys = keys %hash ;
foreach my $key ( @keys ) {
my ( $newkey = $key ) =~ s/^test/something/ ;
$hash{$newkey} = $hash{$key} ;
delete $hash{$key} ;
}
可能有更短的版本，但这应该可以。
【讨论】：
$hash{$newkey} = delete $hash{$key};节省一些字符
$hash{$newkey} = $hash{$key} ; 和 delete $hash{$key} ; 可以合并为一行：$hash{$newkey} = delete $hash{$key} ;。