如何在perl中删除等于第二个数组中某个元素的数组元素

Question

只是想知道是否给了我两个数组 A 和 B，如何删除/删除 A 中也可以在 B 中找到的那些元素？最有效的方法是什么？

另外，作为一种特殊情况，如果 B 是 A 上 grep 之后的结果数组，该怎么做？当然，在这种情况下，我们可以在否定条件上执行grep。但是在 perl 中是否有类似对另一个数组进行补码的东西？

谢谢。

Answer 1

每当您想到found in 时，您可能正在寻找哈希。在这种情况下，您将创建 B 值的散列。然后你会 grep A，检查每个元素的哈希值。

my @A = 1..9;
my @B = (2, 4, 6, 8);
my %B = map {$_ => 1} @B;

say join ' ' => grep {not $B{$_}} @A; # 1 3 5 7 9

如您所见，perl 通常不会自己维护任何类型的found in 表， 所以你必须提供一个。上面的代码可以很容易地包装成一个函数，但为了效率，最好内联。

Answer 2

查看none、all、part、notall 可通过List::MoreUtils 获得的方法。您可以使用本模块中提供的方法执行几乎任何集合操作。

Perl Training Australia有一个很好的教程

Answer 3

如果您要求最有效的方式：

my @A = 1..9;
my @B = (2, 4, 6, 8);

my %x;
@x{@B} = ();
my @AminusB = grep !exists $x{$_}, @A;

但您会注意到我的和Eric Strom 的solution 之间的区别仅适用于更大的输入。

您可以找到方便的这种函数式方法：

sub complementer {
  my %x;
  @x{@_} = ();
  return sub { grep !exists $x{$_}, @_ };
}

my $c = complementer(2, 4, 6, 8);

print join(',', $c->(@$_)), "\n" for [1..9], [2..10], ...;

# you can use it directly of course
print join(' ', complementer(qw(a c e g))->('a'..'h')), "\n";

Answer 4

使用哈希可能会更好，但也可以使用smart matching。窃取Eric Strom的例子，

my @A = 1..9;
my @B = (2, 4, 6, 8);

say join ' ' => grep {not $_ ~~ @B } @A; # 1 3 5 7 9

Answer 5

同样，您可能最好使用散列，但您也可以使用Perl6::Junction。再次盗用Eric Strom的例子，

use Perl6::Junction qw(none);

my @A = 1..9;
my @B = (2, 4, 6, 8);

say join ' ' => grep {none(@B) == $_} @A; # 1 3 5 7 9

Answer 6

正如Eric Strom 已经提到的，每当您需要搜索特定的内容时，如果您有哈希值总是会更容易。

Eric 有一个更好的解决方案，但可能难以理解。我希望我的更容易理解。

# Create a B Hash

my %BHash;
foreach my $element (@B) {
   $BHash{$element} = 1;
}

# Go through @A element by element and delete duplicates

my $index = 0;
foreach my $element (@A) {
   if (exists $BHash{$element}) { 
      splice @A, $index, 1;    #Deletes $A[$index]
      $index = $index + 1;
   }
}

在第一个循环中，我们简单地创建一个以@B 中的元素为键的散列。

在第二个循环中，我们遍历@A 中的每个元素，同时跟踪@A 中的索引。