将两个哈希合并为一个[重复]

Question

我通过调用递归方法process_node处理了几个XML文件：

    for my $file (@ARGV) {
            my $doc = XML::LibXML->load_xml(location => $file);

            my $report;
            my $items = [];

            process_node($doc->getDocumentElement, $report, $items);

            print Dumper($items);
    }

它们都有相似的结构：

• 一个名为CalRunnerReport 的大父节点，其属性为BSN、ProjectName、StationName
• 还有很多名为TestItem的子节点

我正在尝试准备一个由变量 $items- 引用的哈希数组，用作 DataTables.net（一个 HTML 表格组件）的数据源：

sub process_node($$$) {
        my ($node, $report, $items) = @_;

        return unless $node->nodeType == XML_ELEMENT_NODE;

        if ($node->nodeName eq 'CalRunnerReport') {
                my $attr = get_attributes($node);
                $report = {
                        BSN         => $attr->{BSN},
                        ProjectName => $attr->{ProjectName},
                        StationName => $attr->{StationName},
                }
        } elsif ($node->nodeName eq 'TestItem') {
                my $attr = get_attributes($node);
                push @$items, [      # XXX fails to create a hash
                        %$report,
                        %$attr,
                ];
        }

        for my $child ($node->getChildnodes) {
                process_node($child, $report, $items);
        }
}

sub get_attributes($) {
        my $node = shift;
        my $attr = {};

        for my $a ($node->attributes) {
                my $key = $a->name;
                my $val = $a->value;
                $attr->{$key} = $val;
        }

        return $attr;
}

但是在Data:Dumper 输出中，我看到上面的push 语句没有创建哈希，而是创建了一个列表：

      [
        'BSN',
        '1147386447',
        'ProjectName',
        'R089',
        'StationName',
        'B',
        'ExecutionTime',
        '00:00:00',
        'Result',
        'PASS',
        'EndTime',
        '03/09/2013 21:00:03',
        'StartTime',
        '03/09/2013 21:00:03',
        'Name',
        'RecordOperationParameter'
      ],
      [
        'BSN',
        '1147386447',
        'ProjectName',
        'R089',
        'StationName',
        'B',
        'ExecutionTime',
        '00:00:00',
        'Result',
        'PASS',
        'EndTime',
        '03/09/2013 21:00:03',
        'StartTime',
        '03/09/2013 21:00:03',
        'Name',
        'ClearLimitTestPendingList'
      ]

有没有一种很好的方法可以将%$report 和 %$attr 的 2 个哈希值组合成一个哈希值 - 而无需遍历它们的所有密钥？

Answer 1

你想要这样的东西：

push @$items, { %$report, %$attr };

顺序很重要 - 在这种情况下，任何共享键都将具有来自 $attr 的值，而不是来自结果哈希中的 $report 的值。