Perl - 使用变量引用与使用变量副本推入数组

Question

问题：为什么我不能将元素推送到一个二维数组中，该数组位于解析 SQL 结果集的 while 循环内？

我需要一些帮助来了解为什么会发生这种情况。数据存储到二维数组的方式可以有多种方式，但就我的目的而言，我需要使用 push 方法。

下面是一些有效的代码：

my @tt = (0,1,2,3);
my @t;
push (@t,\@tt);
print "[0][0]:".$t[0][0]."\n";
print "[0][1]:".$t[0][1]."\n";
print "[0][2]:".$t[0][2]."\n";
print "[0][3]:".$t[0][3]."\n";
@tt = (4,5,6,7);
push (@t,\@tt);
print "[1][0]:".$t[1][0]."\n";
print "[1][1]:".$t[1][1]."\n";
print "[1][2]:".$t[1][2]."\n";
print "[1][3]:".$t[1][3]."\n";

输出是：

-------------------------
[0][0]:0
[0][1]:1
[0][2]:2
[0][3]:3
[1][0]:4
[1][1]:5
[1][2]:6
[1][3]:7

---

这是我遇到的问题

我正在运行一些 SQL 来构建一个包含 X 列数的结果集。要将数据存储到我的数组中，我想我可以使用与上面相同的语法：

while (@results=$sth->fetchrow_array())
{
    push(@stu_pool,\@results);
} 

我测试了 SQL 并检查了结果集，所以问题与此无关。我也回到了长期的方法，这让我得到了我想要的最终结果。我没有使用push(@stu_pool,\@results);，而是在循环中使用了这段代码：

$stu_pool[$index][0] = $results[0];
$stu_pool[$index][1] = $results[1];
$stu_pool[$index][2] = $results[2];
$stu_pool[$index][3] = $results[3];
$stu_pool[$index][4] = $results[4];
$stu_pool[$index][5] = $results[5];
$stu_pool[$index][6] = $results[6];
$index++;

那么是什么阻止我将元素推入这个数组？它适用于第一个示例，但是当我尝试打印出元素时，它们都是空白的。我正在使用的代码：

print "[0][0]:".$stu_pool[0][0]."\n";
print "[0][1]:".$stu_pool[0][1]."\n";
print "[0][2]:".$stu_pool[0][2]."\n";
print "[0][3]:".$stu_pool[0][3]."\n";
print "[1][0]:".$stu_pool[1][0]."\n";
print "[1][1]:".$stu_pool[1][1]."\n";
print "[1][2]:".$stu_pool[1][2]."\n";
print "[1][3]:".$stu_pool[1][3]."\n";

重复：

为什么 push 方法在 while 循环中不起作用？

Answer 1

让我稍微改变一下你的第一个例子。

my @tt = (0,1,2,3);
my @t;
push (@t,\@tt);
@tt = (4,5,6,7);
push (@t,\@tt);
print "[0][0]:".$t[0][0]."\n";
print "[0][1]:".$t[0][1]."\n";
print "[0][2]:".$t[0][2]."\n";
print "[0][3]:".$t[0][3]."\n";
print "[1][0]:".$t[1][0]."\n";
print "[1][1]:".$t[1][1]."\n";
print "[1][2]:".$t[1][2]."\n";
print "[1][3]:".$t[1][3]."\n";

输出：

[0][0]:4
[0][1]:5
[0][2]:6
[0][3]:7
[1][0]:4
[1][1]:5
[1][2]:6
[1][3]:7

您没有将@tt 复制到@t。您将对变量@tt 的引用放入@t。因此，当@tt 发生其他事情时，它也会在通过@t 获取时发生变化。要真正制作副本，您需要 push(@t,[@tt]) 或 @{$t[$i]} = @tt（如果 $i 是适当的索引变量）。

或者对于另一个例子，试试push(@stu_pool, [@results]);

Answer 2

只有一个@results - 你让@stu_pool 的每个元素都引用同一个@results，它（最后一次检查循环条件）最终将被设置为包含() .

您想要添加my：while (my @results = $sth->fetchrow_array) { 可以正常工作，因为现在每次循环时，@results 都是一个不同的数组。

Answer 3

为什么要循环？这样做更容易：

my $results = $sth->fetchall_arrayref();

或者如果你坚持使用数组变量：

my @results = @{$sth->fetchall_arrayref()};