如何将数组项的哈希值发送到csv

Question

哈希值的哈希值正确打印到 csv，但数组值哈希值的哈希值弄乱了我的 csv 文件。请在下面找到我的代码不起作用。

<    use strict;
     use warnings;
     use Data::Dumper;

     my %student_hash;
     my $student_report = "StudentReport.csv";

     %student_hash = (
            'RollNummber1' => {
                               'studentname' => 'Boris',
                               'address' => ['Vietnam',
                                             'local'
                                            ],
                               'DOB' => '5june2000'

                               },
            'RollNummber2' => {
                               'studentname' => 'John',
                               'address' => [ 
                                             '4th/floor',
                                             'Culverdown/Street',
                                             'WestHam',
                                             'UK.',
                                            ],
                               'DOB' => '2feb2000'

                               },
            'RollNummber3' => {
                               'studentname' => 'Karen',
                               'DOB' => '5march2000'

                              }
           );

          print "StudentHash:".Dumper(\%student_hash);

          open(my $fh, '>', $student_report) or die("Couldn't open ile");
          print $fh "DOB \t,ADDRESS \t,NAME \t\n";

          foreach my $key(keys %student_hash){
           foreach my $secondkeys (keys %{$student_hash{$key}}){

             if($secondkeys =~ /DOB || studentname/) {
               print $fh "$student_hash{$key}{$secondkeys} \t,"; } 
             if($secondkeys =~ /address/) {
               print $fh Dumper $student_hash{$key}{$secondkeys} }; 
        }
    print $fh "\n";
 }
 close($fh);>

如果我注释掉打印数组部分，那么代码可以正常工作。有人可以建议如何在一个单元格或多个单元格中将数组元素打印到 csv 中。谢谢

Answer 1

使用Text::CSV - 如果您有要打印的数组引用，您可以使用print。 （它为您处理报价）。

或者您可以使用column_names 设置列顺序，并使用print_hr 以该顺序输出哈希引用。

看起来你并不担心RollNumber，所以你可以作弊：

foreach my $student ( values %student_hash ) { 

}

迭代。我不清楚你想用address 做什么。但是一个简单的join 可能就可以解决问题。 （在换行或空格上，取决于所需的输出）。

#!/usr/bin/env perl
use strict;
use warnings;
use Text::CSV;

my %student_hash = (
    'RollNummber1' => {
        'studentname' => 'Boris',
        'address'     => [ 'Vietnam', 'local' ],
        'DOB'         => '5june2000'

    },
    'RollNummber2' => {
        'studentname' => 'John',
        'address' => [ '4th/floor', 'Culverdown/Street', 'WestHam', 'UK.', ],
        'DOB'     => '2feb2000'

    },
    'RollNummber3' => {
        'studentname' => 'Karen',
        'DOB'         => '5march2000'

    }
);

my $csv = Text::CSV->new( { sep_char => ',', eol => "\n" } );
$csv->column_names( 'studentname', 'DOB', 'address' );
foreach my $student ( values %student_hash ) {
    if ( defined $student -> {address} ) { 
        $student -> {address} = join (" ", @{$student->{address}});
    }

    $csv->print_hr( \*STDOUT, $student );
}