Perl 将数组的哈希值与另一个数组进行比较

Question

我正在尝试将所有数组值（完整数组）与哈希值（数组）进行比较，如果找到匹配项，则将哈希键推送到新数组。 下面的代码比较哈希值是否不是数组，但如果是数组，我该如何比较？

%hash=(
       storeA=>['milk','eggs'],
       storeB=>['milk','fruits','eggs','vegetables'],
       storeC=>['milk','fruits','eggs'],
      );

@array = (
        'fruits',
        'milk',
        'eggs'
    );

要比较的代码

use strict;
use warnings;
use Data::Dumper;

foreach my $thing (@array)   {
     foreach ((my $key, my $value) = each %hash)   { 
                 if ($value eq $thing)   {
                       push @new_array, $key;
                }
          }
   }
  print Dumper(\@new_array);

预期输出

@new_array = (
               storeB,
               storeC
       );

Answer 1

求两个集合的交集，如果它的元素个数是数组元素个数，你要存key：

#!/usr/bin/perl
use warnings;
use strict;


sub intersect {
    my ($arr1, $arr2) = @_;
    my %intersection;
    $intersection{$_}{0}++ for @$arr1;
    $intersection{$_}{1}++ for @$arr2;
    return grep 2 == keys %{ $intersection{$_} }, keys %intersection
}


my %hash = (
            storeA => [qw[ milk eggs ]],
            storeB => [qw[ milk fruits eggs vegetables ]],
            storeC => [qw[ milk fruits eggs ]],
           );

my @array = qw( fruits milk eggs );

my @new_array;

while (my ($store, $arr) = each %hash) {  # while, not for!
    push @new_array, $store if @array == intersect(\@array, $arr);
}

use Data::Dumper;
print Dumper(\@new_array);

Answer 2

您还可以使用all 和any 的组合形式List::Util：

while ((my $key, my $value) = each %hash) {
    if ( all { my $temp = $_; any { $_ eq $temp } @$value } @array ) {  
        push @new_array, $key;
    }
}

因此，您在这里寻找@array 的所有元素都存在于哈希中的给定数组中的情况。

Answer 3

遍历所有存储（键）并为每个检查是否所有数组元素都在键的数组引用中。

use strict;
use warnings;

my %inventory = (
    storeA => ['milk','eggs'],
    storeB => ['milk','fruits','eggs','vegetables'],
    storeC => ['milk','fruits','eggs'],
);    
my @items = ('fruits', 'milk', 'eggs');

my @found;
foreach my $store (keys %inventory) {
    push @found, $store 
        if @items == grep { in_store($_, $inventory{$store}) } @items
}   

sub in_store { for (@{$_[1]}) { return 1 if $_[0] eq $_ }; return 0; }

print "@found\n";  # prints:  storeB storeC

grep 块检查每个项目是否（可用）在存储中，以及通过的数量是否等于存储的所有项目并被添加的项目数（数组大小）。请注意，子例程返回最后评估的值而没有显式返回，因此不需要最终的return。为了清楚起见，添加了它。

Answer 4

试试这个。我在这里做了一个小技巧。 grep 用于过滤数组中的元素。

我创建了变量$joined_array，其中包含| 分隔的@array 数据。然后我将变量传递给 grep。

诀窍是，当数组与标量数据进行比较时，比较行为是数组元素与标量数据的总数。

my @array = qw(one two three);

if(@array == 3)
{
    print "Hi\n";

}

这里的条件在内部运行为3 == 3。

我在这里做的同样的逻辑。

use warnings;
use strict;
my %hash=(
    "storeA"=>['milk','eggs'],
    "storeB"=>['milk','fruits','eggs','vegetables'],
    "storeC"=>['milk','fruits','eggs'],
);

my @array = (
    'fruits',
    'milk',
    'eggs'
);

my @new_array;

my $joined_array = join("|",@array);

foreach (keys  %hash)
{

 push(@new_array,$_) if  ((grep{ /\b$joined_array\b/ } @{$hash{$_}}) >= scalar @array);

}

print "$_\n" for @new_array

Answer 5

我将从每个商店的库存数组中构建一个散列。这是一种浪费的方法，但只要真实数据不是很大，就不会太严重

像这样。内部 grep 语句计算 @list 中该商店可用的商品数量，并将其与列表中的商品数量进行比较，如果所有商品都有库存，则返回 true

如果这是真实情况（我怀疑这是家庭作业），那么出于我能想到的所有实际目的，%stocks 哈希应该包含 哈希 每家商店可用的商品 p>

use strict;
use warnings 'all';

my %stocks = (
    storeA => [ qw/ milk eggs / ],
    storeB => [ qw/ milk fruits eggs vegetables / ],
    storeC => [ qw/ milk fruits eggs / ],
);

my @list = qw/ fruits milk eggs /;

my @stores = grep {
    my %stock = map { $_ => 1 } @{ $stocks{$_} };
    grep($stock{$_}, @list) == @list;
} keys %stocks;

use Data::Dump;
dd \@stores;

输出

["storeB", "storeC"]