perl 打开文件名中带有变量的文件

Question

我尝试打开文件夹中的文件列表。最终我想在其中插入一个 HTML 片段。到目前为止，我可以打开文件夹并读取数组中的列表。没关系。但是当我尝试使用变量作为文件名打开文件时，每次都会收到一条错误消息（“权限被拒绝”）。无论我是否使用 $_ 或其他将列表项的值放入变量的变体。我在这里找到了类似的问题，但到目前为止还没有找到解决方案。这是我的代码：

use strict;
use warnings;

my ($line);

opendir (FOLDER,"path/to/folder/./") or die "$!";
my @folderlist = readdir(FOLDER);
my @sorted_folderlist = sort @folderlist;
close(FOLDER);

foreach (@sorted_folderlist) {
  my $filename = $_;
  open (READ, ">", "path/to/folder/$filename") or die "$!";
  # do something
  close (READ);
}

这里有什么错误？以及如何使用变量作为文件名打开文件？

普约恩

这是我为了回答 1 而更改的代码：

my $dh; 
opendir $dh, "dir/./" or die ... 
my @folderlist = grep { -f "dir/$_" } readdir $dh; 
close $dh; 
my @sorted_folderlist = sort @folderlist; 

foreach my $filename (@sorted_folderlist) { 
  open my $fh, "<", "dir/$filename" or die ... 
  open my $writeto, ">", "new/$filename" or die ... 
  print $writeto "$fh"; 
  close $fh; 
  close $writeto; 
}

Answer 1

您的代码中有几个问题。

第一个导致错误的原因可能是readdir() 也会返回. 和..，但这些是目录。所以你试着写信给directory/.。

其次，您的错误消息包含$!，这很好，但您不输出文件名。那么你就会看到你的错误了。

第三，你调用一个你打开的文件句柄来写READ。

另外，现在你应该使用词法文件句柄。

use strict;
use warnings;

opendir my $dh, "dir" or die $!;
# read all files, not directories
my @folderlist = grep { -f "dir/$_" } readdir $dh;
close $dh;
my @sorted_folderlist = sort @folderlist;

foreach my $filename (@sorted_folderlist) {
    open my $fh, ">", "dir/$filename" or die "Could not write to dir/$filename: $!";
    print $fh "foo...\n";
    close $fh;
}

Answer 2

您已在 tinita's answer 中清除了错误和良好做法。

我想评论一个可能的改进，即使用完整路径构建文件列表。

• 在readdir 的输出上使用map 将目录添加到每个文件，然后对其进行过滤

  my @files = grep { -f } map { "$dir/$_" } readdir $dh;
  

  或者，在map 块中实现grep 的（过滤）功能

  my @files = map { my $fp = "$dir/$_"; -f $fp ? $fp : () } readdir $dh;
  

  如果$fp 不是-f，我们将返回一个空列表，该列表在输出中被展平，从而消失。

• 使用glob，直接给你完整路径^†

  use File::Glob ':bsd_glob';
  my @files = grep { -f } glob "$dir/*";
  

  File::Glob 的 bsd_glob() 覆盖 glob 并很好地处理名称中的空格。

请注意区别：glob 中的 * 不会选择以点 (.) 开头的条目。如果您也想要这些，请将其更改为 glob "$dir/{*,.*}"。请参阅链接的 File::Glob 文档。

---

更新 更正问题的编辑（添加），也在 cmets 中讨论

一旦完整路径文件名被读入@files

foreach my $file (@files) {
    my $out_file = 'new_' . $file;
    open my $writeto '>', $outfile or die "Can't open $outfile: $!";
    open my $fh,     '<', $file    or die "Can't open $file: $!";
    while (my $line = <$fn>) {
        # process $line and build what need be written to the new file
        my $new_line = ...   
        print $writeto $new_line;
    }
    close $writeto;
    close $fh;
}

（或者，如果文件名不是完整路径，则在 open 调用中构建完整路径。）

文件句柄在再次打开时会关闭，因此您只需要为最后一个文件提供明确的close。然后你可以在循环之前声明my ($fh, $writeto);变量，使用open $fh ...（没有my），然后关闭文件句柄。但是你有这些变量在foreach 范围之外。

文档：

• Files and I/O in perlintro

• perlopentut 和 open（和print）

• <> operator in perlop

---

^†glob "$dir/*" 带有注入错误的可能性，对于非常特殊的目录名称。 虽然这只能通过相当不寻常的名称来实现，但使用 escape sequence 会更安全

my @files = grep { -f } glob "\Q$dir\E/*"

由于这也会转义空格，因此不需要带有 bsd_glob() 的 File::Glob。