Perl：在哈希数组中找到最大值和最小值

Question

我在 Perl 中有以下结构：

#!/usr/bin/perl
use strict;
use warnings;

my %hash = (
    'firstitem' => {
        '1' => ["A","99"],
        '2' => ["B","88"],
        '3' => ["C","77"],
    },
    'seconditem' => {
        '3' => ["C","100"],
        '4' => ["D","200"],
        '5' => ["E","300"],
    },
);

我正在寻找一种方法来找到每个哈希数组中的最大数和最小数。 所以输出将是

firstitem: max:99, min:77
seconditem: max:300, min:100

我的想法是先对辅助键进行排序，然后在 for 循环中进行冒泡排序或其他排序。它看起来不是很优雅和聪明。

    foreach my $k1 (keys %hash) {
        my $second_hash_ref = $hash{$k1};                   
        my @sorted_k2 = sort { $a <=> $b } keys %{$second_hash_ref}; 
        foreach my $i (0..$#sorted_k3){ 
            #bubble sort or other sort
        }
    }

Answer 1

List::Util是提供min和max功能的核心模块：

use strict;
use warnings;

use List::Util qw(min max);

my %hash = (
    'firstitem' => {
        '1' => ["A","99"],
        '2' => ["B","88"],
        '3' => ["C","77"],
    },
    'seconditem' => {
        '3' => ["C","100"],
        '4' => ["D","200"],
        '5' => ["E","300"],
    },
);

for my $key (keys(%hash)) {
    my @numbers = map { $_->[1] } values(%{$hash{$key}});
    printf("%s: max: %d, min: %d\n", $key, max(@numbers), min(@numbers));
}

输出：

firstitem: max: 99, min: 77
seconditem: max: 300, min: 100

Answer 2

你快到了。

一旦您进入第二级，您需要的是整个数字列表，以便能够找到批次的最大值和最小值。由于您需要子键中所有数组的极值，因此您无需遍历二级键。

此外，您可以获取所有数组内容，除非该数字保证在特定位置。然后使用grep 和Scalar::Util::looks_like_number 过滤掉不是数字的元素。

最后，对键进行排序没有任何好处。

use warnings;
use strict;
use feature 'say';

use Scalar::Util 'looks_like_number';
use List::MoreUtils 'minmax';

my %hash = ( 
    'firstitem' => {
        '1' => ["A","99"], '2' => ["B","88"], '3' => ["C","77"],
    },  
    'seconditem' => {
        '3' => ["C","100"], '4' => ["D","200"], '5' => ["E","300"],
    },  
);


foreach my $k1 (keys %hash) 
{
    my @nums = 
        grep { looks_like_number($_) } 
        map  { @{ $hash{$k1}{$_} } }
        keys %{$hash{$k1}};

    my ($min, $max) = minmax @nums;

    say "$k1: max = $max, min = $min";
}

这将打印预期值。如果您的真实哈希与显示的完全一样，您可以通过values %{$hash{$k1}} 直接提取arrayrefs，并使用map { @$_ } 取消引用它们。

由于您需要两个极端，所以最适合的就是 minmax 和 List::MoreUtils，这是“最有效的算法”。该算法的性能在 XS 版本的模块中完全实现，而 Perl 版本有一些开销。

还要注意核心 List::Util 模块，其中单独的 min 和 max 以及其他实用程序。