在 ASCII 上按日期对 PERL 数组进行排序

Question

我需要做的是编写一个脚本来读取目录列表 然后对它们进行排序，最后一个目录将被“弹出”。

我的 $last_one = pop @sorted;

然后最后一个目录将被删除 - 使用 system("rm- rf $last_one) 或 删除树（$last_one）。

 1  #!/usr/bin/perl
 2  use strict;
 3  use warnings;
 4
 5  my $dir_to_process = "/production/log/fo/archive/";
 6  opendir DH, $dir_to_process or die "Sorry, this is not going to work out $!";
 7
 8  while (my $name = readdir DH) {
 9       next if $name =~ /^\./;
10       push(my @unsorted,$name) ;
11       my @sorted_dir = sort @unsorted;
12       foreach my $sorted (@sorted_dir) {
13       print "$sorted\n";
14       sleep 1 ;
15       }
16
17  }

但是，我在对目录进行排序时遇到了很多麻烦 - 它们是用这种格式编写的。 这是实际的输出。

2013Nov12
2013Sep14
2013Jul15
2013Jan20
2013Sep11
2013May31
2013Jul04
2012Dec09
2013Oct12
2013Oct09
2012Dec27
2013Nov28
2013Mar24
2013Jun06
2013Jun25

Answer 1

sort() 接受代码块，您可以在其中定义自己的排序算法。只需将您的目录名称转换为时间戳即可。这就像
sort { date2stamp($a) <=> date2stamp($b) } @unsorted
在 date2stamp 子中使用 POSIX::mktime() 为日期字符串创建正确的时间戳。

Answer 2

您需要一个函数将目录名称转换为日期（将日期信息拆分为您可以排序的内容：年、月、日）。

这是一个例子

sub parsedate {
  my $name = shift;
  my %months = ( 'Jan'=> 1, 'Feb' => 2, 'Mar' => 3, 'Apr' => 4,
    'May'=> 5, 'Jun' => 6, 'Jul' => 7, 'Aug' => 8,
    'Sep'=> 9, 'Oct' => 10, 'Nov' => 11, 'Dec' => 12 );

  my ($y,$m,$d);
  $name =~ m/^(\d{4})(\w{3})(\d{2})$/ 
    and ($y,$m,$d) = ($1,$months{$2},$3)
    or die "file name $name doesn't match";

  return sprintf("%04d%02d%02d",$y,$m,$d);
}

现在您可以使用您的新子 parsedate 对它们进行排序。

my @sorted_dir = sort {parsedate($a) <=> parsedate($b)} @unsorted;

Answer 3

将月份名称转换为数字，然后从 y m d 中生成一个数字 然后按数字对数字进行排序 “schwartzian 变换”用于将数字附加到文件名

#!/usr/bin/perl
#
#
use warnings;
use strict;

my %monthval=qw(Jan 01 Feb 02 Mar 03 Apr 04 May 05 Jun 06 Jul 07 Aug 08 Sep 09 O
ct 10 Nov 11 Dec 12);


my @in=qw(2013Nov12
2013Sep14
2013Jul15
2013Jan20
2013Sep11
2013May31
2013Jul04
2012Dec09
2013Oct12
2013Oct09
2012Dec27
2013Nov28
2013Mar24
2013Jun06
2013Jun25);

my @sorted = map{$_->[0]} sort { $a->[1] <=> $b->[1]}  map { my ($y,$m,$d)=/(\d{
4})(\w{3})(\d{2})/; [$_,"$y".$monthval{$m}."$d"]} @in;

foreach my $name (@sorted) {
  print "$name\n";
}

Answer 4

让我们假设存在一个函数convert_date，它将您的日期转换为 YYYYMMDD 格式。如果你有那个，一个简单的字符串比较会找到最旧的。

my ($oldest) =
   sort { convert_date($a) cmp convert_date($b) }
   @dirs;

更快：

my ($oldest) =
   map $_->[0],
   sort { $a->[1] cmp $b->[1] }
   map [ $_, convert_date($_) ],
   @dirs;

最快：

my ($oldest) =
   map substr($_, 8),
   sort
   map convert_date($_) . $_,
   @dirs;

---

但是排序 (O(N log N)) 是一种寻找一个元素 (O(N)) 的浪费方式。

my $oldest = $dirs[0];
for (@dirs) {
   $oldest = $_ if convert_date($_) lt $oldest;
}

更快？

use List::Util qw( minstr );
my $oldest = substr(minstr( map { convert_date($_) . $_ } @dirs ), 8);

---

现在，剩下的就是写convert_date。

use Carp qw( croak );

my %month_num_by_en_name = (
   Jan => 1,  Feb =>  2,  Mar =>  3,  Apr =>  4,
   May => 5,  Jun =>  6,  Jul =>  7,  Aug =>  8,
   Sep => 9,  Oct => 10,  Nov => 11,  Dec => 12,
);


sub convert_date {
   my ($date) = @_;

   my ($y,$m,$d) = $date =~ m/^(\d{4})(\w{3})(\d{2})\z/
      or croak("Invalid input");

   $m = $month_num_by_en_name{$m}
      or croak("Invalid input");

   return sprintf("%04d%02d%02d", $y,$m,$d);
}

您也可以使用DateTime::Format::Strptime。这样可以更轻松地支持其他语言。

use DateTime::Format::Strptime qw( );

my $format = DateTime::Format::Strptime->new(
   pattern  => '%Y%b%d',
   locale   => 'en_US',
   on_error => 'croak',
);

sub convert_date {
   my ($date) = @_;
   return $format->parse_datetime($date)->strftime('%Y%m%d');
}