【问题标题】：Perl: Add hash as sub hash to simple hashPerl：将哈希作为子哈希添加到简单哈希
【发布时间】：2020-12-08 06:56:58
【问题描述】：

我查看了其他两个似乎与此相关的问题，但它们有点迟钝，我无法将它们与我想做的事情联系起来，我认为这更简单。我也认为这将是一个非常常见的问题/任务的更清晰的陈述，所以我发布这个是为了像我这样的其他人的利益。

问题：

我有 3 个文件，每个文件都有 key=value 对的列表：

settings1.ini

key1=val1
key2=val2
key3=val3

settings2.ini

key1=val4
key2=val5
key3=val6

settings3.ini

key1=val7
key2=val8
key3=val9

毫不奇怪，我想将这些 key=value 对读入哈希中以对其进行操作，所以...

我有一个文件名的哈希：

my %files = { file1 => 'settings1.ini'
            , file2 => 'settings2.ini'
            , file3 => 'settings3.ini'
            };

我可以像这样遍历文件名：

foreach my $fkey (keys %files) {
    say $files{$fkey};
}

好的。

现在我想将每个文件中的 key=value 对列表添加到哈希中，作为每个相应“顶级”文件名键下的子哈希，这样我就可以像这样遍历它们：

foreach my $fkey (keys %files) {
    say "File: $files{$fkey}";
    foreach my $vkey (keys $files{$fkey}) {
        say "  $vkey: $files{$fkey}{$vkey}";
    }
}

换句话说，我想向散列添加第二层，使其不再是（在伪术语中）单层值列表：

file1 => settings1.ini
file2 => settings2.ini
file3 => settings3.ini

成为一个多层值列表：

file1 => key1 => 'val1'
file1 => key2 => 'val2'
file1 => key3 => 'val3'

file2 => key1 => 'val4'
file2 => key2 => 'val5'
file2 => key3 => 'val6'

file3 => key1 => 'val7'
file3 => key2 => 'val8'
file3 => key3 => 'val9'

地点：

my $fkey = 'file2';
my $vkey  = 'key3';
say $files{$fkey}{$vkey};

将打印值

'val6'

作为旁注，我正在尝试使用File::Slurp 读取key=value 对。在单级哈希上执行此操作很好：

my %new_hash = read_file($files{$fkey}) =~ m/^(\w+)=([^\r\n\*,]*)$/img;

但是 - 重新表述整个问题 - 我真正想做的是将 key=value 对的新哈希“嫁接”到顶部 $file 键下的现有文件名哈希上作为“子/分支” ' 子哈希。

问题：

我该怎么做，如何像这样一次一层地构建多级哈希？
我是否可以在不必预先将哈希预定义为多层的情况下执行此操作？

我use strict;等我看到了

Can't use string ("string") as a HASH ref while "strict refs" in use at script.pl line <lineno>.

我不完全理解...

编辑：

感谢 Timur Shtatland、Polar Bear 和 Dave Cross 的精彩回答。在精神上分析您的建议时，我突然想到我在最初的问题中有些不一致，从而稍微误导了您。我道歉。我也想我现在明白为什么我看到了“严格的裁判”错误。我做了一些改变。

请注意，我第一次提到文件名的初始哈希是正确的。然而，随后循环通过%files 的foreach 示例是不正确的，因为我从使用file1 作为第一个文件密钥到使用settings1.ini 作为第一个文件密钥。我认为这就是 Perl 抛出 strict refs 错误的原因——因为我试图将键从初始字符串更改为指向子哈希的 hash_ref（反之亦然）。

我理解对了吗？

【问题讨论】：

标签： perl hash tree key fileslurp

【解决方案1】：

有几个用于 ini 文件的 CPAN 模块。你应该研究什么是可用的，然后选择你内心想要的。

否则你可以按照sn-p的精神编写自己的代码

use strict;
use warnings;
use feature 'say';

use Data::Dumper;

my @files = qw(settings1.ini settings2.ini settings3.ini);

my %hash;

for my $file (@files) {
    $hash{$file} = read_settings($file);
}

say Dumper(\%hash);

sub read_settings {
    my $fname = shift;
    my %hash;
    
    open my $fh, '<', $fname
        or die "Couldn't open $fname";
    
    while( <$fh> ) {
        chomp;
        my($k,$v) = split '=';
        $hash{$k} = $v
    }
    
    close $fh;
    
    return \%hash;
}

输出

$VAR1 = {
          'settings1.ini' => {
                               'key2' => 'val2',
                               'key1' => 'val1',
                               'key3' => 'val3'
                             },
          'settings2.ini' => {
                               'key2' => 'val5',
                               'key1' => 'val4',
                               'key3' => 'val6'
                             },
          'settings3.ini' => {
                               'key1' => 'val7',
                               'key2' => 'val8',
                               'key3' => 'val9'
                             }
        };

【讨论】：

【解决方案2】：

要一次构建一层哈希，请使用匿名哈希。这里%files的每一个值都是一个hash的引用，例如$files{'settings1.ini'}：

# read the data into %new_hash, then:
$files{'settings1.ini'} = { %new_hash }

您无需预先将散列定义为多层（作为散列的散列）。

另外，避免重新发明轮子。将 Perl 模块用于常见任务，在这种情况下，请考虑使用 Config::IniFiles 之类的东西来解析 *.ini 文件

另请参阅：

匿名哈希：perlreftut
哈希的哈希：perldsc

【讨论】：

谢谢帖木儿。我选择 .ini 文件作为示例只是因为它们是最熟悉的情况之一，但它可以是任何具有 key=value 对的文件。我不想重新发明轮子，所以感谢该模块的链接。
你得到了@Timur 的投票，因为它添加了一对大括号以使其成为匿名哈希并且有效:)

【解决方案3】：

Perl 让这样的事情变得非常简单。

#!/usr/bin/perl

use strict;
use warnings;
use feature 'say';
use Data::Dumper;

my %files;

# <> reads from the files given on the command line
# one line at a time.
while (<>) {
  chomp;
  my ($key, $val) = split /=/;

  # $ARGV contains the name of the file that
  # is currently being read.
  $files{$ARGV}{$key} = $val;
}

say Dumper \%files;

运行如下：

$ perl readconf settings1.ini settings2.ini settings3.ini

给出以下输出：

$VAR1 = {
          'settings3.ini' => {
                               'key2' => 'val8',
                               'key1' => 'val7',
                               'key3' => 'val9'
                             },
          'settings2.ini' => {
                               'key3' => 'val6',
                               'key1' => 'val4',
                               'key2' => 'val5'
                             },
          'settings1.ini' => {
                               'key3' => 'val3',
                               'key1' => 'val1',
                               'key2' => 'val2'
                             }
        };

【讨论】：