IPC::Open3 的问题

Question

我正在使用 IPC::Open3 编写一个简单的脚本。该脚本不会对 stdout 或 stderr 产生任何输出，而我希望对两者都有输出。

完整的源代码：

#!/usr/bin/env perl 

use strict;
use warnings;
use utf8;

use IPC::Open3;

pipe my $input, my $output or die $!;
my $pid =  open3(\*STDIN, $output, \*STDERR, 'dd', 'if=/usr/include/unistd.h') or die $!;

while(<$input>) {
    print $_."\n";
}
waitpid $pid, 0;

我相当肯定我在错误地使用 IPC::Open3。但是，我仍然对自己应该做什么感到困惑。

Answer 1

这是pipe。不知道它为什么在那里，我不能说更多。这很好用。

my $reader;
my $pid =  open3(\*STDIN, $reader, \*STDERR, 'dd', 'if=/usr/include/unistd.h') or die $!;

while(<$reader>) {
    print $_."\n";
}
waitpid $pid, 0;

我意识到这可能只是一个例子，但万一不是......这对你正在做的事情来说完全是矫枉过正。您可以使用反引号来实现。

print `dd if=/usr/include/unistd.h`

---

IPC::Open3 有点过于复杂。还有更好的模块，比如IPC::Run和IPC::Run3。

use strict;
use warnings;

use IPC::Run3;

run3(['perl', '-e', 'warn "Warning!"; print "Normal\n";'],
     \*STDIN, \*STDOUT, \*STDERR
);

Answer 2

您的程序存在以下问题：

• \*STDIN（打开STDIN作为连接到孩子STDIN的管道）应该是<&STDIN（使用父母的STDIN作为孩子的STDIN）。
• \*STDERR（打开STDERR作为连接到孩子STDERR的管道）应该是>&STDERR（使用父母的STDERR作为孩子的STDERR）。
• 您在$output 中放置的值将被忽略和覆盖。幸运的是，它被正确的值覆盖了！
• 您使用print $_."\n";，但$_ 已经换行终止。先chomp，或者不添加换行符。
• open3 不是系统调用，所以它没有设置$!。
• open3 出错时不返回 false；它会引发异常。

所以我们得到类似的东西：

#!/usr/bin/env perl

use strict;
use warnings;
use feature qw( say );

use IPC::Open3;

my $pid = open3('<&STDIN', my $output, '>&STDERR',
    'dd', 'if=/usr/include/unistd.h');

while (<$output>) {
    chomp;
    say "<$_>";
}

waitpid($pid, 0);