已删除但仍定义？

Question

我正在处理 Perl 中的哈希值，但遇到了一些问题。在我的代码运行一段时间后，它会生成一个类似于以下内容的哈希值：

my %book = (
    +1 => {
        27 => 100,
        24 => 1000,
    },
    -1 => {
        30 => 200,
        31 => 500,
    }
);

在处理更多数据后，代码最终通过使用以下代码行删除了哈希的两个条目：

delete $book{-1}{30};
delete $book{-1}{31};

因此，哈希应该是半空的。但是，稍后在我的代码中运行以下 if 语句：

if ((defined $book{+1}) && (defined $book{-1})){
    do A
}else{
    do B
}

我的代码最终会执行“事情 A”而不是“事情 B”，因为哈希的“-1”侧已被删除，所以他应该这样做。这怎么可能？而且，最重要的是，如何解决这个问题？

Answer 1

删除%{$books{-1}} 中的两个条目后，哈希引用$books{-1} 仍然存在，即使它为空。

use strict;
use warnings;

my %book = (
    +1 => {
        27 => 100,
        24 => 1000,
    },
    -1 => {
        30 => 200,
        31 => 500,
    }
);

delete $book{-1}{30};
delete $book{-1}{31};

use Data::Dump;
dd \%book;

输出：

{ -1 => {}, 1 => { 24 => 1000, 27 => 100 } }

如果您想修剪该条目，则必须为此编写显式逻辑

# Trim Hash
my @empty_keys = grep {!%{$book{$_}}} keys %book;
delete $book{$_} for @empty_keys;

更新

正如 ysth 所建议的，另一种解决方案是测试是否有任何哈希键为空：

if (! grep {!$book{$_} || !%{$book{$_}}} qw(1 -1)) {
    print "A\n";
} else {
    print "B\n";
}

Answer 2

与其删除多余的哈希元素，我更愿意让使用%book 的代码对空哈希具有弹性，这通常并不难做到

我也会非常谨慎地使用带有数字键的哈希，因为有许多字符串可以表示相同的数字。例如，虽然'1' == '1.0' 是true，'1' eq '1.0' 是false，如果这些值被用作哈希键，它们将引用不同的元素

有了这些附加条件，我会写以下内容

很抱歉，我目前只有一台平板电脑可以使用，IDE 不允许我将输出文本复制到此处粘贴。但它已经过测试并且可以正常工作

use strict;
use warnings;

my %book = (
  +1 => {
    27 => 100,
    24 => 1000,
  },
  -1 => {
    30 => 200,
    31 => 500,
  }
);

# $book{-1} becomes an empty hash
delete $book{-1}{30};
delete $book{-1}{31};

# remove elements that have no content
for (keys %book) {
  delete $book{$_} unless keys %{ $book{$_} };
}

use Data::Dumper;
$Data::Dumper::Useqq = 1;
print Dumper \%book;