属性“vpc_id”的值不合适：需要字符串

Question

我正在设置我的第一个 terraform 目标组，目前卡在中间。

这是我的资源代码

resource "aws_lb_target_group" "ami_tg" {
  name     = "ami-lb-tg-${substr(uuid(), 0, 3)}"
  port     = var.tg_port
  protocol = var.tg_protocol
  vpc_id   = var.vpc_id
  health_check {
    healthy_threshold   = var.elb_healthy_threshold
    unhealthy_threshold = var.elb_unhealthy_threshold
    timeout             = var.elb_timeout
    interval            = var.elb_interval
  }
}

显然我传递给了我的 variable.tf 文件

variable "tg_port" {}
variable "tg_protocol" {}
variable "elb_healthy_threshold" {}
variable "elb_unhealthy_threshold" {}
variable "elb_timeout" {}
variable "elb_interval" {}
variable "vpc_id" {}

然后添加到我的 root/main.tf 模块文件中

   module "alb" {
  source                  = "./alb"
  tg_port                 = 80
  tg_protocol             = "HTTP"
  vpc_id                  = module.networking.vpc_id
  elb_healthy_threshold   = 2
  elb_unhealthy_threshold = 2
  elb_timeout             = 3
  elb_interval            = 30
}

但是每当我运行 terraform plan 时，我都会收到以下错误；

Error: Incorrect attribute value type

  on alb/main.tf line 16, in resource "aws_lb_target_group" "ami_tg":
  16:   vpc_id   = var.vpc_id
    |----------------
    | var.vpc_id is object with 19 attributes

Inappropriate value for attribute "vpc_id": string required.

这里的任何建议将不胜感激

Answer 1

你的输出：

output "vpc_id" { 
    value = aws_vpc.HH_vpc
}

返回整个 HH_vpc 对象，而不仅仅是它的ID。只返回 id 它应该是：

output "vpc_id" { 
    value = aws_vpc.HH_vpc.id
}