无法在 google_monitoring_alert_policy 中为使用 Terraform 的 GCP 警报策略添加多个条件答案

【问题标题】：Not able to add multiple conditions in google_monitoring_alert_policy for GCP alerting policy using Terraform无法在 google_monitoring_alert_policy 中为使用 Terraform 的 GCP 警报策略添加多个条件
【发布时间】：2021-03-29 06:39:39
【问题描述】：

请让我知道如何通过 Terraform 在 GCP 警报政策中提及多个条件。我尝试了几种方法来创建文档中提到的条件列表，但没有任何效果。

下面是sn-p的代码：

resource "google_monitoring_alert_policy" "alert_policy" {
  display_name = "Request count Policy"
  combiner     = "OR"
  conditions   = [
    display_name = "Request count condition"
    condition_threshold  {
      filter          = "metric.type=\"run.googleapis.com/request_count\" AND resource.type=\"cloud_run_revision\" AND metric.label.response_code_class=\"4xx\" AND resource.label.service_name=\"dev-ms\""
      duration        = "60s"
      comparison      = "COMPARISON_GT"
      threshold_value = 5
      trigger = {
        count = 1
      }
      aggregations  {
        alignment_period     = "60s"
        per_series_aligner   = "ALIGN_DELTA"
        cross_series_reducer = "REDUCE_SUM"
        group_by_fields      = ["metric.label.response_code_class", "resource.label.revision_name"]
      }
    },
    display_name = "Request latencies condition"
    condition_threshold {
      filter          = "metric.type=\"run.googleapis.com/request_count\" AND resource.type=\"cloud_run_revision\" AND metric.label.response_code_class=\"4xx\" AND resource.label.service_name=\"dev-ms\""
      duration        = "60s"
      comparison      = "COMPARISON_GT"
      threshold_value = 5
      trigger = {
        count = 1
      }
      aggregations  {
        alignment_period     = "60s"
        per_series_aligner   = "ALIGN_DELTA"
        cross_series_reducer = "REDUCE_SUM"
        group_by_fields      = ["metric.label.response_code_class", "resource.label.revision_name"]
      }
    }
]
  documentation {
    content = "The cloud run based request count alerting policy."
  }
  notification_channels = [
    google_monitoring_notification_channel.email0.id
  ]

  user_labels = {
    name = "offer-engine-alert-policy"
  }
}

【问题讨论】：

显示您已完成的工作以及错误消息和/或问题详细信息。
嗨，John，似乎存在我无法解决的语法问题。我创建了一个条件列表，但 TF 应用导致错误突出显示“此处不需要条件块* 或 缺少键值分隔符和使用换行符作为块分隔符

标签： google-cloud-platform terraform terraform-provider-gcp

【解决方案1】：

以下语法对我有用。我没有使用 [] 声明一个列表，而是重复了条件块并且它起作用了！！

resource "google_monitoring_alert_policy" "alert_policy" {
  display_name = "Request count Policy"
  combiner     = "OR"
  conditions   {
    display_name = "Request count condition"
    condition_threshold  {
      filter          = "metric.type=\"run.googleapis.com/request_count\" AND resource.type=\"cloud_run_revision\" AND metric.label.response_code_class=\"4xx\" AND resource.label.service_name=\"dev-ms\""
      duration        = "60s"
      comparison      = "COMPARISON_GT"
      threshold_value = 5
      trigger {
        count = 1
      }
      aggregations  {
        alignment_period     = "60s"
        per_series_aligner   = "ALIGN_DELTA"
        cross_series_reducer = "REDUCE_SUM"
        group_by_fields      = ["metric.label.response_code_class", "resource.label.revision_name"]
      }
    }
  }
  conditions   {
    display_name = "Request latencies condition"
    condition_threshold {
      filter          = "metric.type=\"run.googleapis.com/request_count\" AND resource.type=\"cloud_run_revision\" AND metric.label.response_code_class=\"4xx\" AND resource.label.service_name=\"dev-ms\""
      duration        = "60s"
      comparison      = "COMPARISON_GT"
      threshold_value = 5
      trigger  {
        count = 1
      }
      aggregations  {
        alignment_period     = "60s"
        per_series_aligner   = "ALIGN_DELTA"
        cross_series_reducer = "REDUCE_SUM"
        group_by_fields      = ["metric.label.response_code_class", "resource.label.revision_name"]
      }
    }
}
  documentation {
    content = "The cloud run based request count alerting policy."
  }
  notification_channels = [
    google_monitoring_notification_channel.email0.id
  ]

  user_labels = {
    name = "alert-policy"
  }
}

【讨论】：