通过 Terraform 将触发器添加到 AWS Lambda 函数答案

【问题标题】：Add trigger to AWS Lambda functions via Terraform通过 Terraform 将触发器添加到 AWS Lambda 函数
【发布时间】：2021-09-15 14:56:49
【问题描述】：

关注：https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/lambda_function 还有一些在线挖掘，似乎没有办法通过lambda function tf.在我的例子中：在触发 lambda 函数的特定 S3 存储桶上创建任何对象。

有解决办法吗？

【问题讨论】：

使用s3_bucket_notification - 这不是解决方法，而是它应该工作的方式。对于许多其他调用配置，请使用 lambda_event_source_mapping。

标签： terraform terraform-provider-aws

【解决方案1】：

来自documentation，这些是创建 lambda 函数和 S3 触发器所需的资源：

 resource "aws_iam_role" "iam_for_lambda" {
  name = "iam_for_lambda"

  assume_role_policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": "sts:AssumeRole",
      "Principal": {
        "Service": "lambda.amazonaws.com"
      },
      "Effect": "Allow"
    }
  ]
}
EOF
}

resource "aws_lambda_permission" "allow_bucket" {
  statement_id  = "AllowExecutionFromS3Bucket"
  action        = "lambda:InvokeFunction"
  function_name = aws_lambda_function.func.arn
  principal     = "s3.amazonaws.com"
  source_arn    = aws_s3_bucket.bucket.arn
}

resource "aws_lambda_function" "func" {
  filename      = "your-function.zip"
  function_name = "example_lambda_name"
  role          = aws_iam_role.iam_for_lambda.arn
  handler       = "exports.example"
  runtime       = "go1.x"
}

resource "aws_s3_bucket" "bucket" {
  bucket = "your-bucket-name"
}

resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket = aws_s3_bucket.bucket.id

  lambda_function {
    lambda_function_arn = aws_lambda_function.func.arn
    events              = ["s3:ObjectCreated:*"]
    filter_prefix       = "AWSLogs/"
    filter_suffix       = ".log"
  }

  depends_on = [aws_lambda_permission.allow_bucket]
}

【讨论】：