【问题标题】:Delay in creation of launch config in AWS在 AWS 中创建启动配置的延迟
【发布时间】:2019-01-26 16:00:49
【问题描述】:

使用 Terraform,我定义了以下启动配置和自动缩放组资源:

resource "aws_launch_configuration" "lc_name" {
  name = "lc_name"
  image_id = "ami-035d01348bb6e6070"
  instance_type = "m3.large"
  security_groups = ["sg-61a0b51b"]
}

####################
# Autoscaling group
####################
resource "aws_autoscaling_group" "as_group_name" {

  name = "as_group_name"
  launch_configuration = "lc_name"
  vpc_zone_identifier = ["subnet-be1088f7","subnet-fa8d6fa1"]
  min_size = "1"
  max_size = "1"
  desired_capacity = "1"
  load_balancers = ["${aws_elb.elb_name.name}"]
  health_check_type = "EC2"
}

当我运行 terraform apply 时,我得到:

Error: Error applying plan:
1 error(s) occurred:

aws_autoscaling_group.as_group_name: 1 error(s) occurred:
aws_autoscaling_group.as_group_name: Error creating AutoScaling Group: ValidationError: Launch configuration name not found - A launch configuration with the name: lc_name does not exist
status code: 400, request id: b09191d3-a47c-11e8-8198-198283743bc9

Terraform does not automatically rollback in the face of errors.
Instead, your Terraform state file has been partially updated with
any resources that successfully completed. Please address the error
above and apply again to incrementally change your infrastructure.

如果我再次运行 apply,一切顺利,这强烈暗示创建自动缩放组代码识别新的启动配置时存在延迟。有没有办法适应这种延迟?

更新:

根据建议,我添加了一个依赖项:

resource "aws_launch_configuration" "myLaunchConfig" {
  name = "myLaunchConfig"
  image_id = "ami-01c068891b0d9411a"
  instance_type = "m3.large"
  security_groups = ["sg-61a0b51b"]
}

resource "aws_autoscaling_group" "myAutoScalingGroup" {

  name = "myAutoScalingGroup"
  launch_configuration = "myLaunchConfig"
  depends_on = ["myLaunchConfig"]
  vpc_zone_identifier = ["subnet-be1088f7","subnet-fa8d6fa1"]
  min_size = "1"
  max_size = "1"
  desired_capacity = "1"
  load_balancers = ["${aws_elb.myLoadBalancer.name}"]
  health_check_type = "EC2"
}

由于相同的原因仍然出现错误,尽管看起来有点不同:

Error: aws_autoscaling_group.myAutoScalingGroup: resource depends on non-existent resource 'myLaunchConfig'

【问题讨论】:

    标签: terraform


    【解决方案1】:

    据 Terraform 所知,您的自动缩放组和启动配置之间没有任何关系,因此它将尝试并行创建这些,导致观察到的竞争条件在下一个 apply 时自行纠正。

    使用 Terraform,您拥有 two different ways of ordering a dependency chain between resources。

    您可以使用显式的depends_on 语法强制资源等到另一个资源被创建后再创建。

    在你的情况下,这将是这样的:

    resource "aws_launch_configuration" "lc_name" {
      name            = "lc_name"
      image_id        = "ami-035d01348bb6e6070"
      instance_type   = "m3.large"
      security_groups = ["sg-61a0b51b"]
    }
    
    ####################
    # Autoscaling group
    ####################
    resource "aws_autoscaling_group" "as_group_name" {
      name                 = "as_group_name"
      launch_configuration = "lc_name"
      vpc_zone_identifier  = ["subnet-be1088f7", "subnet-fa8d6fa1"]
      min_size             = "1"
      max_size             = "1"
      desired_capacity     = "1"
      load_balancers       = ["${aws_elb.elb_name.name}"]
      health_check_type    = "EC2"
      depends_on           = ["aws_launch_configuration.lc_name"]
    }
    

    或者,如果可能,这通常更可取,如果您从一个资源中插入一个值,那么它将自动等到该资源被创建,然后再创建第二个资源。

    在你的情况下,你会使用这样的东西:

    resource "aws_launch_configuration" "lc_name" {
      name            = "lc_name"
      image_id        = "ami-035d01348bb6e6070"
      instance_type   = "m3.large"
      security_groups = ["sg-61a0b51b"]
    }
    
    ####################
    # Autoscaling group
    ####################
    resource "aws_autoscaling_group" "as_group_name" {
      name                 = "as_group_name"
      launch_configuration = "${aws_launch_configuration.lc_name.name}"
      vpc_zone_identifier  = ["subnet-be1088f7", "subnet-fa8d6fa1"]
      min_size             = "1"
      max_size             = "1"
      desired_capacity     = "1"
      load_balancers       = ["${aws_elb.elb_name.name}"]
      health_check_type    = "EC2"
    }
    

    如果您不确定 Terraform 将执行的操作顺序,那么您可能需要查看 terraform graph command。

    【讨论】:

    • 那是我的错,我在发布之前更改了事物的名称并且错过了一个更改。我现在已经修好了。感谢您提供有关图形命令的信息...为这条有用的信息点赞!
    • 我已经对我的示例进行了相同的更改,但您是说我提到的内容不适用于您使用 depends_on 或依赖资源上的插值吗?
    • 您的depends_on 错误。您需要指定完整的资源名称,例如depends_on = ["aws_launch_configuration.lc_name"]。但理想情况下,您只需从 LC 资源中插入 LC 名称。
    • 对...做到了。通过插值,现在可以正常工作了。
    猜你喜欢
    • 2017-08-02
    • 1970-01-01
    • 2021-03-09
    • 1970-01-01
    • 2019-09-04
    • 1970-01-01
    • 2011-03-04
    • 1970-01-01
    • 1970-01-01
    相关资源
    最近更新 更多